Display all nets Hierarchically per block

Hi Pedro,

Presumably you could do a recursive traversal of the schematic hierarchy (relatively simple if you can just use a switch view list) - I'm sure there are many examples of doing a recursive traversal. Something like this:

procedure(CCFsimpleRecurse(cv @key 
    (viewList "schematic symbol") (excludeLibs list("basic")) visited)
  let((master)
    unless(visited
      visited=makeTable('visited nil)
    )
    foreach(instMaster cv~>instanceMasters
      unless(member(instMaster~>libName excludeLibs) || visited[instMaster]
        if(instMaster~>cellViewType=="schematicSymbol" then
          master=dbOpenCellViewByType(
            instMaster~>libName 
            instMaster~>cellName 
            viewList
          )
        else
          master=nil
        )
        visited[instMaster]=master
        when(master
          CCFsimpleRecurse(
            master
            ?viewList viewList 
            ?excludeLibs excludeLibs 
            ?visited visited
          )
        )
      )
    )
    visited
  )
)

procedure(CCFgetAllSchematics(cv @key 
    (viewList "schematic symbol") (excludeLibs list("basic"))
    )
  let((visited withSch)
    visited=CCFsimpleRecurse(cv ?viewList viewList ?excludeLibs excludeLibs)
    withSch=setof(symbMaster visited visited[symbMaster])
    foreach(mapcar symbMaster withSch visited[symbMaster])
  )
)

Then you could start from the top level schematic and do:

allSchematics=CCFgetAllSchematics(topCV)

(you could open the topCV with dbOpenCellViewByType - no window needed).

Then you have a list of all the schematic cellViews, so you could do a:

foreach(cv allSchematics
  ; do something with each to get all nets - e.g. cv~>nets~>name
)

Andrew

Thanks Andrew.

But how do I pass topCV (I mean the syntax)? I've tried this without success: topCV = hiGetCurrentWindow() .

Kind regards,

Pedro

If the top cellview is open in a window, use topCV=geGetEditCellView() . hiGetCurrentWindow() returns the window identifier, not the cellView (please read the documentation for these functions). If you don't want to open in a window, you can use:

topCV=dbOpenCellViewByType("topLib" "topCell" "topView")

to open the database in SKILL.

Regards,

Andrew

Hi Andrew,

I am sorry, but it is not working for me.

From the CIW:

topCV=dbOpenCellViewByType("pedro" "tb" "schematic")
db:0x3e4ca01a
allSchematics=CCFgetAllSchematics(topCV)
(db:0x423e611a db:0x3b7e2b9a db:0x3e4c299a db:0x3e4cd49a db:0x3e4c8f9a
db:0x3e4c691a db:0x3e4cd49a
)
foreach(cv allSchematics
cv~>nets~>name
)
(db:0x423e611a db:0x3b7e2b9a db:0x3e4c299a db:0x3e4cd49a db:0x3e4c8f9a
db:0x3e4c691a db:0x3e4cd49a
)

Kind regards,

Pedro

Your foreach loop is not doing anything with the list of net names. You either need to print it somehow, or you should use foreach(mapcar ...). For example:

foreach(cv allSchematics
  println(cv~>nets~>name)
)

(use tilde-arrow rather than straight arrow, as otherwise the ->name won't work for each net).

Or:

foreach(mapcar cv allSchematics
  cv~>nets~>name
)

which will give you a list of lists of all the net names for each cellView. 

You could also do:

allSchematics~>nets~>name

to achieve the same thing.

If you're going to write SKILL code, it might be worth following one of the (free) training classes on SKILL Programming on http://support.cadence.com (use Learning→Online Courses to see what's there)

Regards,

Andrew

I think something is not right.

When I enter the commands below ...

deOpenCellView("pedro" "tb" "schematic" "schematic" hiGetSessionWindow(hiGetCurrentWindow()) "r" )
geGetEditCellView()~>nets~>name

I get ....

("gnd!" "vprog" "vref" "out" "in")

which is correct.
However, when I try the recursive algorithm the output of the top level doesn't look right.

topCV=dbOpenCellViewByType("pedro" "tb" "schematic")
db:0x3e4ca01a

allSchematics~>nets~>name
(("O")
("MINUS" "PLUS")
("PLUS" "MINUS")
("IN" "IP" "O" "R" "S")
("n" "p")
("gnd!")
("IN" "IP" "O" "R" "S")
)

here vprog and vref are missing and the function is grabbing names of pins too, not only nets.

Kind regards,

Pedro

Two things:

1. The code as I provided uses a viewList of "schematic symbol". That means that if there's not a schematic view, it finds the symbol view. The CCFgetAllSchematics doesn't really take that into account (the function was badly named - this wasn't supposed to be the final solution - just something to get you started) - after all, I threw it together in a few minutes.
2. Secondly, it doesn't include the top cellView.

You can workaround this by doing:

allSchematics=cons(topCV CCFgetAllSchematics(topCV ?viewList "schematic cmos.sch"))

Note I gave two alternatives for the schematic view name - if you don't do that you get a bunch of warnings if you only give "schematic". You could just do this:

allSchematics=cons(topCV CCFgetAllSchematics(topCV ?viewList "schematic schematic"))

(normally specifying the view name twice is a bit pointless, but it's just a way of suppressing the warning you'd get otherwise).

Andrew

Thanks a lot Andrew. I really appreciate your help.
Kind regards,
Pedro