Required skill help to create circle, triangle, square, pentagon, hexagon donut creation

This is really not clear. By "path segment" do you mean "pathSeg" objects? Because if you do, it won't work because pathSegs are only supported on 45-degree multiples. If you don't mean that, what do you mean? A screenshot of manually drawn shapes would help.

Andrew

Hi Andrew,

Thanks for reply. Please find the image for the shapes which i need help to develop skill code.

Well, this is just usage of dbCreateDonut, dbCreatePathSeg and a bit of maths. I threw together the code below as an illustration. First of all, the CCFcreateDiagPathSeg is just using the suggested approach for creating diagonal pathSegs with octagonal ends as described in the documentation for dbPathSeg. The rest of the functions are each creating the other objects - and all have been written to return a list of the resulting objects. Of course, change the maths to suit your needs - this was just an illustration.

This does seem a rather strange thing to want to do, but I'm sure you have your reasons!

procedure(CCFcreateDiagPathSeg(cv layer width beginPt endPt)
  let((mfgGrid diagWidth halfDiag halfWidth)
    mfgGrid=techGetMfgGridResolution(techGetTechFile(cv))
    diagWidth=round(width*sqrt(2)/mfgGrid)*mfgGrid
    halfDiag=diagWidth/2.0
    halfWidth=width/2.0
    dbCreatePathSeg(cv layer beginPt endPt diagWidth "custom" "custom" 
      list(halfDiag halfDiag list(halfWidth halfWidth halfDiag halfWidth halfWidth halfDiag)))
  )
)

procedure(CCFcreateRing(layer radius width @optional (origin 0:0) (cv geGetEditCellView()))
  ; assume that the radius is the radius of the centre line (there isn't really a centre
  ; line since it's a donut, but the centre of the ring path)
  list(dbCreateDonut(cv layer origin radius+width/2.0 radius-width/2.0))
)

procedure(CCFcreateTriangle(layer bottomLength width @optional (origin 0:0) (cv geGetEditCellView()))
  let((halfBottom)
    destructuringBind((origX origY) origin
      halfBottom=bottomLength/2.0
      list(
        CCFcreateDiagPathSeg(cv layer width origin origX+halfBottom:origY+halfBottom)
        CCFcreateDiagPathSeg(cv layer width origX+halfBottom:origY+halfBottom origX+bottomLength:origY)
        dbCreatePathSeg(cv layer origin origX+bottomLength:origY width "truncate" "truncate")
      )
    )
  )
)

procedure(CCFcreateSquare(layer edge width @optional (origin 0:0) (cv geGetEditCellView()))
  destructuringBind((origX origY) origin
    ; mapcon is like mapcan (it concatenates), but behaves like map (gets the remaining list)
    ; allows us to see the first two points in the remaining list to create the side
    foreach(mapcon remSide list(origin origX:origY+edge origX+edge:origY+edge origX+edge:origY origin)
      when(cdr(remSide)
        list(dbCreatePathSeg(cv layer car(remSide) cadr(remSide) width "extend" "extend"))
      )
    )
  )
)

procedure(CCFcreatePentagon(layer bottomLength sideLength width 
    @optional (origin 0:0) (cv geGetEditCellView()))
  let((halfBottom)
    halfBottom=bottomLength/2.0
    destructuringBind((origX origY) origin
      list(
        CCFcreateDiagPathSeg(cv layer width 
          origX:origY+sideLength origX+halfBottom:origY+sideLength+halfBottom)
        CCFcreateDiagPathSeg(cv layer width 
          origX+halfBottom:origY+sideLength+halfBottom origX+bottomLength:origY+sideLength)
        dbCreatePathSeg(cv layer origin origX:origY+sideLength width "extend" "truncate")
        dbCreatePathSeg(cv layer 
          origX+bottomLength:origY origX+bottomLength:origY+sideLength 
          width "extend" "truncate")
        dbCreatePathSeg(cv layer origin origX+bottomLength:origY width "truncate" "truncate")
      )
    )
  )
)

procedure(CCFcreateHexagon(layer bottomLength sideLength topLength width 
    @optional (origin 0:0) (cv geGetEditCellView()))
  let((topOffset)
    topOffset=(bottomLength-topLength)/2.0
    destructuringBind((origX origY) origin
      list(
        CCFcreateDiagPathSeg(cv layer width 
          origX:origY+sideLength origX+topOffset:origY+sideLength+topOffset)
        CCFcreateDiagPathSeg(cv layer width 
          origX+bottomLength-topOffset:origY+sideLength+topOffset origX+bottomLength:origY+sideLength)
        dbCreatePathSeg(cv layer
          origX+topOffset:origY+sideLength+topOffset
          origX+bottomLength-topOffset:origY+sideLength+topOffset
          width "truncate" "truncate")
        dbCreatePathSeg(cv layer origin origX:origY+sideLength width "extend" "truncate")
        dbCreatePathSeg(cv layer 
          origX+bottomLength:origY origX+bottomLength:origY+sideLength 
          width "extend" "truncate")
        dbCreatePathSeg(cv layer origin origX+bottomLength:origY width "truncate" "truncate")
      )
    )
  )
)

Thank you Andrew for sharing.