How to create a through separator line in a layout form?

Martin,

Form layouts don't have much control - they are intended to be simple and convenient, but don't give the full controls that (say) a Grid layout would. The downside of grid layouts however is that you normally end up having to create the prompts as labels so that the prompts align (otherwise the overall containers align rather than the entry boxes). If I do this (and use 'col_span to span columns), this works:

FORM2=hiCreateLayoutForm( 
  'NPN_ 
  "NPN "
  hiCreateGridLayout( 
    'main_layout
    ?spacing 10 
    ?items 
      list(
        list(
          hiCreateLabel(
            ?name 'SF1lab
            ?labelText "SF1aaaaaaa"
          )
          'row 0 'col 0
        )
        list(
          hiCreateStringField( 
            ?name 'SF1
            ?editable t
          )
          'row 0 'col 1
        )
        list(
          hiCreateSeparatorField(
            ?name 'sep1
          )
          'row 1 'col 0 'col_span 2
        )
        list(
          hiCreateLabel(
            ?name 'SF2lab
            ?labelText "SF2bbbbbbb"
          )
          'row 2 'col 0
        )
        list(
          hiCreateStringField( 
            ?name 'SF2
            ?editable t
          )
          'row 2 'col 1
        )
        list(
          hiCreateLabel(
            ?name 'SF3lab
            ?labelText "SF3ccccccc"
          )
          'row 3 'col 0
        )
        list(
          hiCreateStringField( 
            ?name 'SF3
            ?editable t
          )
          'row 3 'col 1
        )
        list('col_stretch 0 0)
        list('col_stretch 1 1)
      )
  )
)

hiDisplayForm(FORM2)

Regards,

Andrew

Hi Andrew,

For once I might have a simpler solution than yours

Wrapping the separator in an horizontal box layout should work:

FORM2=hiCreateLayoutForm(
'NPN_
"NPN "

hiCreateFormLayout(
'main_layout
?spacing 10
?label_align 'center
?items (list
hiCreateStringField(
?name 'SF1
?prompt "SF1aaaaaaa "
?editable t)
hiCreateHorizontalBoxLayout( 'sep1_wrap_layout
  ?items list( hiCreateSeparatorField( ?name 'sep1)))
hiCreateStringField(
?name 'SF2
?prompt "SF2bbbbbbb"
?editable t)
hiCreateStringField(
?name 'SF3
?prompt "SF3ccccccc"
?editable t)
));main_layout
);display_form
hiDisplayForm(FORM2)

Cheers,

Aurélien

Excellent idea Aurélien. That’s a much simpler solution!

Andrew

Thanks Andrew and Aurelien. Both the ways are good for me.

Martin