hiAddFields: invalid field description in fieldList

I don't get that error, but the issue is that you need to have specified the prompt width for these fields because they have prompts. It works for me... (although the fields are not going to be wide enough with the dimensions you gave).

Far easier is to use layout forms rather than old "app" forms using coordinates, but if you are going to do that you have to provide sufficient information.

Andrew 

Thanks for your reply，Andrew.

Below is the code that would arise warnings：

;;myformtest.il

include "listDev.il"

; Create string entry for the form.

procedure( myformDefineFields()

; Create a button for the form.

listbutton = hiCreateButton(

?name boolfldglb

?buttonText "list device"

?callback "listdev_cb(myformglb)"

)

list( listbutton )

)

;Generate the form

procedure( myformcreateform()

if( !boundp('myformglb)|| (myformglb == nil)

then

myformglb = hiCreateAppForm(

?name'myformglb

?fields myformDefineFields()

?formTitle "My Form"

?buttonLayout'OKCancel

)

myformglb

)

;Display the form

procedure(myformdisplayform()

myformcreateform() ;;; Creation and Display are separate

hiDisplayForm(myformglb)

)

------------------------------------------

The listDev.il is as below:

;;listDev.il

procedure( listdev_cb(form)

;delete additional old fields

hiDeleteFields(form cdr(form->fieldList))

hiAddFields(

form

list(

list(hiCreateStringField(

?name'test1

?prompt "test1") 0:0 60:40)

list(hiCreateStringField(

?name'test2

?prompt "test2") 0:0 60:40)

)

)

)

OK, the problem is that your main form has NOT been created as a 2D form (there were no coordinates in the initial field placement). So it's a 1D form - you cannot then add fields with coordinates to such a form (you can add fields, but they always will appear at the bottom. Secondly, the 2D descriptors for the string fields are incorrect (as I said before) because they are missing the prompt width (which is required since the field has a prompt). Thirdly, the coordinates in the example above would mean that the fields are on top of each other. Fourthly various things have gone wrong when pasting the code (missing spaces, missing quotation marks, missing parentheses). 

Anyway, here's fixed versions of the two files which will behave:

;;myformtest.il
include "listDev.il"

; Create string entry for the form.
procedure( myformDefineFields()
  ; Create a button for the form.
  listbutton = hiCreateButton(
    ?name 'boolfldglb
    ?buttonText "list device"
    ?callback "listdev_cb(myformglb)"
  )
  list( list(listbutton 0:0 200:30))
)

;Generate the form
procedure( myformcreateform()
  if( !boundp('myformglb)|| (myformglb == nil)
    then
      myformglb = hiCreateAppForm(
	?name 'myformglb
	?fields myformDefineFields()
	?formTitle "My Form"
	?buttonLayout 'OKCancel
      )
    myformglb
  )
)

;Display the form
procedure(myformdisplayform()
  myformcreateform() ;;; Creation and Display are separate
  hiDisplayForm(myformglb)
)

listDev.il:

procedure( listdev_cb(form)
  ;delete additional old fields
  hiDeleteFields(form cdr(form->fieldList))
  hiAddFields(
    form
    list(
      list(hiCreateStringField(
	?name 'test1
	?prompt "test1") 0:30 200:30 80)
      list(hiCreateStringField(
	?name 'test2
	?prompt "test2") 0:60 200:30 80)
    )
  )
)

Andrew

Thanks a lot for your patience sorry for my so  many mistakes. It really saves me a lot of debug time.

By the way, do you have any suggestion on which document should I

go for if I encounter  other warnings or errors. So far, my only

reference is the built-in SKILL reference in cadence.