Align rod rectangle created with elementsX and elementsY.

The issue here is that rodCreateRect (in this case) is returning a list of the individual rod objects because of your use of ?elementsX and ?elementsY. You can't align a list of ROD objects to another list. Aligning just one of them in each list won't work either, since there's no alignment between the individual objects.

I added this function to your code which sets up alignments between the objects returned by rodCreateRect (note the comments) and then aligns one of them from each set. This then gives you a persistent alignment between all of the objects. 

; Given the return value of rodCreateRect when it is returning 
; a list of rodObjects, use the documented order (starting at
; upperRight, top to bottom then right to left, ending at
; lowerLeft) to set up alignments between the rectangles.
; note that this is assuming 0 spacing between the objects. That
; would need adjusting if that's not the case.
procedure(alignRodRects(rodRects @key (elementsY 1))
  letseq(((prevRect car(rodRects)) (prevCol prevRect) (index 1))
    foreach(rodRect cdr(rodRects)
      if(mod(index elementsY)==0 then
        rodAlign(
          ?alignObj rodRect ?alignHandle "upperRight"
          ?refObj prevCol ?refHandle "upperLeft"
        )
        prevCol=rodRect
      else
        rodAlign(
          ?alignObj rodRect ?alignHandle "upperLeft"
          ?refObj prevRect ?refHandle "lowerLeft"
        )
      )
      prevRect=rodRect
      index++
    )
    t
  )
)     
        
procedure( alignProc(@key (cvId geGetEditCellView()))
  let( (defaultSize cuFrame alEnc alFrame)

    defaultSize = 2
    alEnc = 3*defaultSize

    cuFrame = rodCreateRect(?cvId cvId ?layer "M1Resdum" ?width defaultSize ?length defaultSize
      ?elementsX 3 ?elementsY 7 ?spaceX 0)

    alFrame = rodCreateRect(?cvId cvId ?layer "M2Resdum" ?width alEnc ?length alEnc
      ?elementsY 3 ?spaceX 0)

    ; add alignments between the objects in each list
    alignRodRects(cuFrame ?elementsY 7)
    alignRodRects(alFrame ?elementsY 3)  

    ; align the lowermost alFrame to the uppermost cuFrame
    rodAlign(
      ?alignObj car(last(alFrame)) ?alignHandle "lowerRight"
      ?refObj car(cuFrame) ?refHandle "upperRight"
    )

) ; let
) ; procedure

Regards,

Andrew

This is perfect!

Thanks,