My code (fill PP in fluid N-GR) works when pasted in the CIW, but doesn't work when modified as a bindkey.

Sorry for the typo mistake, it's the abe* function, not the abs function.

The shown code is working according to the first sentence of the description only when certain constraints are met, i.e. no other NP shapes in the cellview (the code walks over all NP shapes, even those shapes that might be in the cellview before flattening), guardring must be rectangular, etc. It is not fully clear if that is intentional, prevented by design, or unwanted side effects.

IF it is just filling the complete area that is fully enclosed by a certain layer of the currently selected guardring and assuming that the guardring is an instance of e.g. a techlib pcell, then it might be easier to use a graphical approach:
1) temporarily copy the NP shape(s) from the master of the selected guardring to the current cellview with applying the instance transformation (much easier than searching a flattend pile of shapes)
2) use dbLayerHoles to create PP shape(s) that are fully enclosed by the copied NP shapes
3) remove the temporary NP

Alternatively, you could also feed the above shapes from the guardring master to dbLayerHoles directly and apply the instance transformation on the result, so the third step could be omitted.

However, if there is usage of NP inside the guardring (e.g. the guarded transistors), you would still need to apply further processing, as "NP over PP" is probably not allowed in DRC.

abe functions would be preferable if you would like to work on the whole hierarchy, e.g when the ring shapes are in higher/deeper hierarchy and not only in the next hierarchy level; resp. work on the full cellview, not just on selected objects. Also the post processing to exclude the PP where NP exists could be done in the same run without extra effort.

I'd also recommend to prevent usage of the undo functions. The only reliable undo in my opinion is dbSave+dbPurge, but I doubt it is of general applicability.
It is usually much safer to track changes on the cellview and e.g. remove temporaries afterwards instead of creating a mess first and than rely on having it repaired somehow. If complicated, it is also no problem to create a scratchview (dbOpenCellViewByType and passing "s" as mode argument), do the operations there and just copy the final results.

Regards,

PS: The example from above as code:

procedure( fillGR()
	let( (cv tmpshp fig res)
		cv = deGetCellView()
		; 1) copy shapes from selected guardring instances to cellview
		foreach( obj geGetSelectedSet()
			when(obj~>objType=="inst" &&
				obj~>libName=="<guardring libname>" &&
				obj~>cellName=="<guardring cellname>"

				foreach(shp obj~>master~>shapes
					when(shp~>layerName=="NP"
						fig = dbCopyFig(shp cv obj~>transform)
						when(fig tmpshp = cons(fig tmpshp))
					)
				)
			)
		)

		; 2) fill the holes inside the temporaries
		res = dbLayerHoles(cv list("PP" "drawing") tmpshp)
		
		; may work on the created shapes, e.g. select them, put them into current figGroup, etc.
		printf("created: %L\n" res~>??)

		; 3) delete temporaries
		foreach(e tmpshp dbDeleteObject(e))
	); let
)