Exporting Sprobe Data to File

I don't believe there's anything built-in to do this, but this code could be used after simulation has completed:

/* abExportSprobeToS1p.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       May 26, 2020 
Modified   
By         

If you have run an sp analysis and specified some sprobes, you can
use this function to export to a Touchstone .s1p file. For example:

abExportSprobeToS1p("I1" "./data.s1p")

Where I1 is the instance name of the sprobe (note, this needs to be
a simulator name, so I1.I2 etc rather than using schematic names with /)

***************************************************

SCCS Info: @(#) abExportSprobeToS1p.il 05/26/20.15:17:29 1.1

*/

/***************************************************************
*                                                              *
*      (abExportSprobeToS1p instName fileName [?port 'S1]      *
*                     [?result 'sp_sprobe]                     *
*                      [?resultsDir nil])                      *
*                                                              *
* Given an instance name (note, using simulator names with dot *
* separator for hierarchy) and a port name (either S1 or S2),  *
*     write a Touchstone .s1p representing the sprobe data     *
*                                                              *
***************************************************************/

(defun abExportSprobeToS1p (instName fileName @key (port 'S1) (result 'sp_sprobe) 
                                     resultsDir "SSSSg")
  (let (oport closeAfter sigName data (funcName (getCallingFunction 0))
              xVec yVec len value)
    ;--------------------------------------------------------------------
    ; Bit of basic error checking
    ;--------------------------------------------------------------------
    (unless (and
              (or (stringp port) (symbolp port))
              (member (upperCase port) '("S1" "S2")))
      (error "%s: port must be S1 or S2 : %L\n" funcName port))
    (setq sigName (strcat instName "." (upperCase port)))
    (setq data (getData sigName ?result result ?resultsDir resultsDir))
    (unless data
      (error "%s: could not access data %s\n" funcName sigName))
    (unless (drIsWaveform data)
      (error "%s: cannot handle family waveform data for %s\n" funcName sigName))
    (setq xVec (drGetWaveformXVec data))
    (setq yVec (drGetWaveformYVec data))
    (setq len (drVectorLength xVec))
    ;--------------------------------------------------------------------
    ; Cope with fileName being a port already or a string
    ;--------------------------------------------------------------------
    (cond
      ((and (openportp fileName) (outportp fileName))
       (setq oport fileName))
      ((stringp fileName)
       (setq oport (outfile fileName))
       (unless oport
         (error "%s: cannot write to file %s\n" funcName fileName))
       (setq closeAfter t)
       )
      (t
        (error "%s: incorrect filename %L\n" funcName fileName))
      )
    ;--------------------------------------------------------------------
    ; Write the header and then the freq, real, imag data
    ;--------------------------------------------------------------------
    (fprintf oport "! Touchstone Ver. 1.0\n! Number of ports is 1\n")
    (fprintf oport "# Hz\tS\tRI\tR\t50.000000\n")
    (fprintf oport "! SCATTERING PARAMETERS  :\n")
    (for i 0 (sub1 len)
         (setq value (drGetElem yVec i))
         (fprintf oport "%.14g  %.14g  %.14g\n" 
                 (drGetElem xVec i) (real value) (imag value))
         )
    (when closeAfter
      (close oport))
    t
    )
  )