How do I parse all the graphical entities of a schematic symbol from an OLB

Hi andakConsultingLtd ,

Below is an example Tcl script for parsing an OLB file that extracts pin names and pin numbers. You can extend it further to meet your specific requirements.
Hope it helps!

proc dump_pin_name_and_number {libPath} {
set lSession $::DboSession_s_pDboSession
DboSession -this $lSession
set lStatus [DboState]
set NullObj NULL

# Open library
set cLibPath [DboTclHelper_sMakeCString $libPath]
set lSrcLib [$lSession GetLib $cLibPath $lStatus]
if {$lSrcLib == $NullObj} {
puts "ERROR: Unable to open library: $libPath"
return
}

# Iterate packages
set lPkgIter [$lSrcLib NewPackagesIter $lStatus]
set lPackage [$lPkgIter NextPackage $lStatus]
while {$lPackage != $NullObj} {
# Package name
set pkgCStr [DboTclHelper_sMakeCString]
$lPackage GetName $pkgCStr
set packageName [DboTclHelper_sGetConstCharPtr $pkgCStr]

# Iterate devices
set lDeviceIter [$lPackage NewDevicesIter $lStatus]
set lDevice [$lDeviceIter NextDevice $lStatus]
while {$lDevice != $NullObj} {
# Get cell from device
set lDboCell [$lDevice GetCell $lStatus]
# Cell name
set cellCStr [DboTclHelper_sMakeCString]
$lDboCell GetName $cellCStr
set cellName [DboTclHelper_sGetConstCharPtr $cellCStr]

set partIndex 0
set lLibPart [$lDboCell FindPart $partIndex $lStatus]
if {$lLibPart != $NullObj} {
set lPinCount [$lLibPart GetPinCount $lStatus]
for {set i 0} {$i < $lPinCount} {incr i} {
set lSymPin [$lLibPart GetPin $i $lStatus]

# Pin Name
set pinNameCStr [DboTclHelper_sMakeCString]
$lSymPin GetPinName $pinNameCStr
set pinName [DboTclHelper_sGetConstCharPtr $pinNameCStr]

# Pin Number (mapped by device)
set pinNumCStr [DboTclHelper_sMakeCString]
$lDevice GetPinNumber $i $pinNumCStr
set pinNumber [DboTclHelper_sGetConstCharPtr $pinNumCStr]

puts [format "Package=%s Cell=%s PinIndex=%d Name=%s Number=%s" \
$packageName $cellName $i $pinName $pinNumber]
}
}

set lDevice [$lDeviceIter NextDevice $lStatus]
}
delete_DboPackageDevicesIter $lDeviceIter

set lPackage [$lPkgIter NextPackage $lStatus]
}
delete_DboLibPackagesIter $lPkgIter
}

# Example usage:
# dump_pin_name_and_number {C:\TCL\demo.OLB}