Howto include a text-file (eg. S-parameters or LRCG file) in a library and track its location automatically for netlisting ?

" However the mtline or the nport component require the absolute path of the file to be specified "

You can use the file name only and set the include path in your ADE environment. 

Chris.

I've been meaning to reply to this for a while, just didn't have the chance to get my code adapted and tested.

Anyway, here's some SKILL to solve this. See the comments at the top which explain what you need to do to get an nport which allows you to refer to a s-parameter file contained within a lib/cell/view.

/* abNportFromViewProc.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Oct 08, 2009 
Modified   
By         

A customized netlist procedure to specify the s-parameter file from
a lib/cell/view combination. Typically the referenced view will be
a "text" view.

To set up, copy nport from analogLib into your own library, then
edit the Base CDF:

Add these parameters:

sparamLib  - string - parseAsCEL=no, parseAsNumber=no
sparamCell - string - parseAsCEL=no, parseAsNumber=no
sparamView - string - parseAsCEL=no, parseAsNumber=no

Remove the file parameter

In the spectre simInfo, remove file from otherParameters, and add
sparamLib sparamCell sparamView. Change the netlist procedure to
abNportFromViewProc

***************************************************

SCCS Info: @(#) abNportFromViewProc.il 10/08/09.16:28:54 1.1

*/

defun(abNportFromViewProc (inst)
    let((formatter netlister numPins sparamLib sparamCell sparamView 
	ddId)
	;------------------------------------------------------------
	; get hold of the formatter and netlister objects
	;------------------------------------------------------------
	formatter=nlGetFormatter(inst)
	netlister=nlGetNetlister(formatter)
	nlPrintInstComments(formatter inst)
	nlPrintInstName(formatter inst)
	;------------------------------------------------------------
	; Get information about the nport
	;------------------------------------------------------------
	numPins=atoi(nlGetParamStringValue(inst "p"))
	sparamLib=nlGetParamStringValue(inst "sparamLib")
	sparamCell=nlGetParamStringValue(inst "sparamCell")
	sparamView=nlGetParamStringValue(inst "sparamView")
	;------------------------------------------------------------
	; Netlist the variable number of pins
	;------------------------------------------------------------
	nlPrintString(netlister " (")
	for(pin 1 numPins
	    nlPrintString(netlister 
		strcat(
		    nlGetTerminalSignalName(inst sprintf(nil "p%d" pin))
		    " "
		    nlGetTerminalSignalName(inst sprintf(nil "m%d" pin))
		    " "
		)
	    )
	)
	nlPrintString(netlister ")")
	nlPrintModelName(formatter inst)
	;------------------------------------------------------------
	; Output the path to the s-parameter file in the 
	; s-parameter view
	;------------------------------------------------------------
	nlPrintInstParameters(formatter inst)
	ddId=ddGetObj(
	    sparamLib
	    sparamCell
	    sparamView
	    "*"
	    )
	when(ddId
	    nlPrintString(netlister " file=\"")
	    nlPrintString(netlister ddId~>readPath)
	    nlPrintString(netlister "\"")
	)
    ))

Regards,

Andrew.

Of course - this was just an example. I cut it down to keep it simple; there are other fields that may not make sense - for example, romDatFile (rarely used these days, because it's only for interp=rational which isn't needed much), and so on. But it's just to illustrate the principle.

So yes, you could easily add something like your suggestion, Andrew. BTW, you'd need to print the quotes around the filename, rather like I did in my code.

What I do when posting code (at least anything other than a few lines) is to use the "HTML" button and then put <code><pre> and </pre></code> around the code I'm pasting in. It comes out scrambled in the email, but on the forum site it looks good and is easy to cut and paste.

Regards,

Andrew.

And that solution's one of mine!

Andrew.

Thank you very much.

At my side I worked out a solution, that is very similar, except that inside my custom netlisting function I get the cell view and library automatically form the parent of the instance being netlisted (I did the same with the mtline), then copy the required file from its location in the library to the location of the netlisting directory and then call the original netlisting procedure.

The advantage is that the netlisting directory is then self-contained.