How to achieve data conversion?

Converting an integer to hex is easy enough - sprintf(nil "%x" intVal) - and you can use sscanf() to go in the opposite direction. For binary strings, you could use the following code:

/* abBinaryStrToInt.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Feb 11, 2011 
Modified   
By         

Use bit field functions to convert to and from binary strings.

Two functions:

abBinaryStrToInt("1011") => 11
abIntToBinaryStr(11 4) => "1011"

***************************************************

SCCS Info: @(#) abBinaryStrToInt.il 02/11/11.11:56:48 1.1

*/

/***************************************************************
*                                                              *
*                    abBinaryStrToInt(str)                     *
*                                                              *
*    Take a string of 1s and 0s and convert to an integer.     *
*                                                              *
***************************************************************/

procedure(abBinaryStrToInt(str "t")
    let((len (result 0))
	len=strlen(str)
	when(len>32 error("Cannot convert more than 32 bits"))
	for(i 1 len
	    setqbitfield1(result case(substring(str i 1)
		("1" 1)
		("0" 0)
		(t error("Illegal character %s in binary string" substring(str i 1)))
		)
		len-i
	    )
	)
	result
    )
)


/***************************************************************
*                                                              *
*          abIntToBinaryStr(val @optional (bits 32))           *
*                                                              *
*    Take an integer and convert to a string of 1s and 0s.     *
*    An optional width of the resulting string can be given    *
*                                                              *
***************************************************************/

procedure(abIntToBinaryStr(val @optional (bits 32) "xx")
    let(((result ""))
	when(bits>32 error("Cannot convert more than 32 bits"))
	for(i 0 (sub1 bits)
	    result=strcat(if(onep(bitfield1(val i)) "1" "0") result)
	)
	result
    )
)

Thank you very much. Then how can I trasform the string to variable. For example the result is x="01001"

I want it become x=0b01001 then I can use x<1> x<2>........

I think your answer really help me. Now I have solved problem. I used to think that there must be some command to get the binary code. But after think through your answer and some test I found I can use x<1>,x<2> to directly express the code.

Thank you a lot!