skill - write a file with skill variables

this seems to work

    myPort = outfile( "runSimulation" )
    fprintf(myPort "%s %s %s" tool_opt  multiThread  paraReduction )
    close(myPort)

Hi,

One thing that I would add is that this is fine if you are sure that the variables are all strings, but if not then it may be better to use "%L" for each of the format specifiers - if the variable was not a string then the %s format would cause fprintf (or sprintf or printf) to choke and fail, but %L can be used for any value, 'nil', a list, an integer, a floating point number etc.  You can use the "type" function to obtain the type of a variable, or individual predicate functions like "stringp", "listp" etc. to programmatically test and avoid such an issue also.  E.g.

if(forall(var list(tool_opt multiThread paraReduction) stringp(var)) then
  ;; print variables out nicely if they are all strings
  fprintf(myPort "%s %s %s\n" tool_opt  multiThread  paraReduction )
else
  ;; print values out using default %L format if they are not all strings
  fprintf(myPort "%L %L %L\n" tool_opt  multiThread  paraReduction )
)

You could even build the format string based on the variable data type (that seems overkill here).

Regards,

Lawrence.

I was not able to get the  api  functions to work

Thanks for the tip!

Well, there must have been something wrong in your code, because it works. I would definitely avoid what you're doing, because if something changes in the internal data structures, your code will break. Here's what I had:

procedure(myPreRun(session sdb mode test)
  let((tests testSession asiSession mtOption uniMode psrSwitch)
    tests=axlGetTests(sdb)
    foreach(testName cadr(tests)
      if(axlGetEnabled(axlGetTest(sdb testName)) then
        printf("test %s is enabled\n" testName)
        testSession=axlGetToolSession(session testName)
        asiSession=sevEnvironment(testSession)
        printf("testSession: %L asiSession: %L\n" testSession asiSession)
        mtOption=asiEnvGetVal(asiSession "turboOpts" "mtOption")
        uniMode=asiEnvGetVal(asiSession "turboOpts" "uniMode")
        psrSwitch=asiEnvGetVal(asiSession "turboOpts" "psrSwitch")
        printf("High perf options: MT: %L uniMode: %L paraRed: %L\n"
          mtOption uniMode psrSwitch
        )
      )
    )
  t
  )
)

; axlSessionDisconnect(sess 'myPreRun)
; axlSessionConnect(sess "preRun" 'myPreRun)

Yes.

That said, it's not that important - I was just making the function have a simple, well-defined, return value (t means "true" in SKILL); without this it would have returned the return value of the foreach, which is the list it is iterating over.

You can miss out the t if you want.

Regards,

Andrew.