How to change line styale in Wave scan wave form

Your message is a bit confusing because you're talking about wavescan (which was the waveform tool in IC5141) and ViVA (the waveform tool in IC615). Anyway, the most likely problem is that the definition of the packets used in the display.drf for the y0 to y9 drawing layers. In some PDKs these are defined to be dotted/dashed lines. ADE uses these layers to probe any outputs plotted on the schematic so that the nets are highlighted with the same colour/style as they are plotted in the waveform window. So it's ADE doing this.

The packets will be defined in the display.drf - probably  coming from your PDK. So you may need to change the definitions in the PDK's display.drf (the technology file will define what packet name is used for each layer purpose).

Regards,

Andrew.

 Sorry for the confusion. I meant Viva because I use IC615. I went ahead and edited the disply.drf by going to the CIW > display resource manager > edit and changed the layers styles for y0 -yo to solid but still when I plot on the schematic, I see dotted lines. Is there any skill command to fix this issue.

My guess is that you changed the wrong packets - I just tried this and it worked fine (I did it interactively). I could see the line styles on the nodes highlighted in the schematic change, and once I replotted the waveforms they also were correct (you have to replot to see the change),

Anyway, this code might help. Make your schematic window the current window, and then call this function. It finds the packet names for the y0-y9 drawing layers in the technology associated with your schematic window, and then alters those packets.

Regards,

Andrew.

/* abSetY09LineStyle.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Feb 03, 2005 
Modified   A.D.Beckett
By         Apr 08, 2013 

Function for setting the line style on the y0 to y9
layers conveniently.

Modified to allow the packet names to be obtained from
the tech file, as some technologies use non-standard packet names
for y0 to y9

***************************************************

SCCS Info: @(#) abSetY09LineStyle.il 04/08/13.07:05:49 1.2

*/

/***************************************************************
*                                                              *
*     abSetY09LineStyle([?lineStyle "solid"] [?cvId cvId])     *
*                                                              *
*         Sets the line style of the y0 to y9 layers.          *
*      For example, use with "thickLine" as the argument       *
*       to set the lines to be thick, or "solid" (or no        *
*              argument) to make them thin again.              *
*                                                              *
***************************************************************/

procedure(abSetY09LineStyle(@key (lineStyle "solid") (cvId geGetEditCellView()))
    let((display packet tfId LP packetName)
        tfId=techGetTechFile(cvId)
        unless(tfId error("Could not obtain tech file for cellView %L\n" cvId))
        display=drGetDisplay("display")
        ;----------------------------------------------------------------
        ; Check that the specified line style exists
        ;----------------------------------------------------------------
        unless(drGetLineStyle(display lineStyle)
            error("%s is not a valid line style" lineStyle)
        ) ; unless   
        ;----------------------------------------------------------------
        ; Iterate through y0 to y9
        ;----------------------------------------------------------------
        for(layerNum 0 9
            LP=techGetLP(tfId list(sprintf(nil "y%d" layerNum) "drawing"))
            when(LP 
                packetName=techGetLPPacketName(LP)
                ;------------------------------------------------------------
                ; Ensure the packet exists
                ;------------------------------------------------------------
                unless(
                    member(packetName drGetPacketList(display)) 
                    error(sprintf(nil "%s is not a valid packet" packetName))
                ) ; unless
                ;------------------------------------------------------------
                ; Get current packet and update
                ;------------------------------------------------------------
                packet=drFindPacket(display packetName)
                drSetPacket(display nth(1 packet) nth(2 packet)
                    lineStyle nth(4 packet) nth(5 packet))
            )
        ) ; for
        hiRedraw()
        t
    ) ; let
) ; procedure