Bindkey for layers below mouse cursor

Hello Brian,

In IC615 and IC616 exists an assistant (Window -> Assistants -> Dynamic Selection) which shows all shapes under cursor hierarchically in an assistant window..

By typing ctrl <key> h you can freeze the display of the assistant window and select a shape there (if its in edit mode).

Regards,

Werner

Thanks Werner!

Unfortunately I'm using an old process in 5.1.4.  The technologies that had this bindkey enabled were also in 5.1x, so I know it's possible.  Any thoughts on how to list the layers under the cursor in 5.1.4?

I'll definitely give that a shot in IC61x though!

Brian 

Brian,

How about this? I just threw it together (so not too much testing):

/* CCFlayersUnderCursor.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Nov 07, 2013 
Modified   
By         

Display the layers under the cursor - assume that
you'd call this from a bindkey. This is not needed
in IC61X since you have the dynamic selection assistant,
but might be useful in IC5141.

Call:

CCFlayersUnderCursor()

***************************************************

SCCS Info: @(#) CCFlayersUnderCursor.il 11/07/13.18:52:07 1.1

*/

procedure(CCFlayersUnderCursor()
  let((point overlaps win cv shape lpps
      (lppsUsed makeTable('lppsUsed nil)))
    win=hiGetCurrentWindow()
    when(win
        cv=geGetEditCellView(win)
        point=hiGetPoint(win)
        when(point
          overlaps=dbGetTrueOverlaps(cv list(point point) t 32)
          ;--------------------------------------------------------------
          ; Collect the layer purpose pairs used in a table
          ;--------------------------------------------------------------
          foreach(overlap overlaps
            shape=if(listp(overlap) car(last(overlap)) overlap)
            when(shape~>lpp
                lppsUsed[shape~>lpp]=t
            )
          )
          ;--------------------------------------------------------------
          ; Sort into alphanumerical order based on layer then purpose
          ;--------------------------------------------------------------
          lpps=sort(lppsUsed->?
            lambda((a b) 
              case(alphaNumCmp(car(a) car(b))
                (1 nil)
                (-1 t)
                (t minusp(alphaNumCmp(cadr(a) cadr(b))))
              )
            )
          )
          ;--------------------------------------------------------------
          ; Convert to colon-separated strings of layer and purpose
          ; and then display in a list box
          ;--------------------------------------------------------------
          lpps=foreach(mapcar lpp lpps buildString(lpp ":"))
          if(lpps then
            hiDisplayListBox(
              'CCFlayersUnderCursorListBox
              "Layers under cursor"
              lpps
              ""
            )
          else
            printf("No shapes under cursor\n")
          )
        )
    )
  )
)

Perfect!  I haven't tested it much, but it works out of the box.

I actually prefer to just print the layers to the CIW rather than display in the box, so I added a flag noBox to skip the display list box, and a simple printf("%L\n" lpps) after the if(! noBox) block.

Many thanks!! 

Glad I didn't spend too long doing a fancy form - I originally had it printing to the CIW too and thought I'd just add a simple form to display the results. Anyway, glad it does what you want!

Regards,

Andrew