How to plot one signal versus another in ViVa (to get an eye diagram)

Well, that worked for me - the issue is that you'll get a flyback drawn from the end of each period back to the beginning of the next - maybe that's why it is messy?

Anyway, an alternative would be to use the code below. If I have a signal called "jitter", which has a period of 80n, then if I do:

abChangeXAxis(v("jitter" ?result "tran") xval(v("jitter" ?result "tran"))/80n)

and then use the Eye Diagram to produce an eye with a period of 1, it will effectively do what you want. The code will produce a waveform where the X-axis has been scaled to give UI as the time-axis, and then an eye diagram of that would do what you expect (although it's still reported as time). That could be addressed by doing:

procedure(abWaveVsUI(wave period)
  let((newX yVec)
    newX=xval(wave)/period
    yVec=drGetWaveformYVec(newX)
    yVec->units="UI"
    yVec->name="UI"
    abChangeXAxis(wave newX)
  )
)

This alters the axis properties so that they now in units of UI (and the axis is called UI for completeness too).

Anyway, here's the code for abChangeXAxis:

/* abChangeXAxis.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       May 25, 1999 
Modified   May 21, 2002 
By         A.D.Beckett

Function to change the X Axis of a waveform to the corresponding
Y values of the second variable.

Also function to transpose the X and Y axes of a waveform.

Now handles families, and can be registered as a special function.
Just call:

abRegChangeXAxis()

to add to the calculator.

***************************************************

SCCS Info: @(#) abChangeXAxis.il 11/27/08.09:59:36 1.3

*/

/*******************************************************************
*                                                                  *
*                    (abChangeXAxis yVar xVar)                     *
*                                                                  *
* Return a new waveform object with the x axis set to the y values *
*                     of the second argument.                      *
*                                                                  *
*******************************************************************/

(procedure (abChangeXAxis yVar xVar)
  (let (newWave)
    (cond
      ;------------------------------------------------------------------
      ; Handle normal waveform
      ;------------------------------------------------------------------
      ((drIsWaveform yVar)
       (setq newWave (drCreateEmptyWaveform))
       (drPutWaveformXVec newWave (drGetWaveformYVec xVar))
       (if (eq (drGetWaveformXVec yVar) (drGetWaveformXVec xVar))
         ;---------------------------------------------------------------
         ; if the x axes are the same for both, it's simple
         ;---------------------------------------------------------------
         (drPutWaveformYVec newWave (drGetWaveformYVec yVar))
         ;---------------------------------------------------------------
         ; otherwise need to use value() to interpolate
         ;---------------------------------------------------------------
         (let (xVec yVec len)
           (setq xVec (drGetWaveformXVec xVar))
           (setq len (drVectorLength xVec))
           (setq yVec (drCreateVec (drGetWaveformYType yVar) len))
           (for ind 0 (sub1 len)
                (drAddElem yVec (value yVar (drGetElem xVec ind)))
                )
           (drPutWaveformYVec newWave yVec)
           )
         )
       newWave
       )
      ;------------------------------------------------------------------
      ; Handle family
      ;------------------------------------------------------------------
      ((famIsFamily yVar)
       (famMap 'abChangeXAxis yVar xVar)
       ) ; is family
      (t
        (error "abChangeXAxis - can't handle %L\n" yVar)
        )
      ) ; cond
    ) ; let
  ) ; defun

/**********************************************************************
*                                                                     *
*                         (abRegChangeXAxis)                          *
*                                                                     *
* Registers abChangeXAxis as a new special function in the calculator *
*                                                                     *
**********************************************************************/

(procedure (abRegChangeXAxis)
  (calRegisterSpecialFunction
    (list "abChangeXAxis" 'abChangeXAxisCB)
    )
  t
  )

/***************************************************************************
*                                                                          *
*                            (abChangeXAxisCB)                             *
*                                                                          *
* Callback function for the special function - which builds the expression *
*                                                                          *
***************************************************************************/

(procedure (abChangeXAxisCB)
  (calSpecialFunctionInput 'abChangeXAxis '(STACK))
  )

/***************************************************************
*                                                              *
*                     (abTransposeXY var)                      *
*                                                              *
*             Swap the X and Y axes of a variable              *
*                                                              *
***************************************************************/

(procedure (abTransposeXY var)
  (let (newWave)
       (setq newWave (drCreateEmptyWaveform))
       (drPutWaveformXVec newWave (drGetWaveformYVec var))
       (drPutWaveformYVec newWave (drGetWaveformXVec var))
       newWave
       )
  )

Regards,

Andrew.