Customized histogram for MC

Hi Vinay,

There is currently no way to exclude outliers from the histogram. There is an enhancement CCR for this, 1158568. Some capability was added in IC616 ISR6 to filter evaluation and simulation errors from the yield and histogram data (you can access this by Right Mouse Button menu over the Error column in the Yield view, or in the grey bar at the top of the yield view), but nothing to set limits. Hopefully this will be added in IC617 when we add some more generic filtering capability (hopefully).

You also cannot set a bin to be in a specific place. You sort of could do this in the past with the old histo function (replaced in IC616 with histogram2D) which allowed you to set the min and max and the number of bins. The function still works, but is going to be removed in a future release. It sort of allows filtering of results too - but it's a bit clunky.

Anyway, one way to solve this would be to use the SKILL code below. Load this code from your .cdsinit, and then plot the histogram as normal from ADE XL. Then over the name of the signal in the waveform tool, do Right Mouse->Send to Calculator. You'll end up with an expression something like this in the calculator:

histogram2D((statGetWaveform "Current_C3_0" nil ?resDbFile axlGetHistoryResults(axlGetCurrentHistory(_vivaGetSessionName())) ?testName "AC" ?filtPointsList "") 10 "standard" "stddev" t)

Around the (statGetWaveform ...) bit, insert abFilterByValue (highlighted in red):

histogram2D(abFilterByValue((statGetWaveform "Current_C3_0" nil ?resDbFile axlGetHistoryResults(axlGetCurrentHistory(_vivaGetSessionName())) ?testName "AC" ?filtPointsList "") 2.1m 4.5m) 10 "standard" "stddev" t)

The two numbers are the min and max values for your filter. Alternatively you could strip off everything but the (statGetWaveform...) call, add the abFilterByValue around it, and then use the histogram2D function in the calculator to reconstruct the histogram - and then you can plot this from the calculator.

A bit manual, but hopefully good enough for now until we build this in properly.

Kind Regards,

Andrew.

/* abFilterByValue.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Feb 02, 2015 
Modified   
By         

Filter outliers from a waveform (by value). Useful for histogram
plotting. For example:

abFilterByValue((statGetWaveform "Current_C3_0" nil ?resDbFile 
    axlGetHistoryResults(axlGetCurrentHistory(_vivaGetSessionName())) ?testName "AC" ?filtPointsList "") 
    8.29m 8.295m
)

***************************************************

SCCS Info: @(#) abFilterByValue.il 02/02/15.11:27:19 1.1

*/

/**********************************************************************
*                                                                     *
*                   (abFilterByValue wave min max)                    *
*                                                                     *
* Filter a waveform by value. If any points are outside the range min *
*         to max, they are omitted from the output waveform.          *
*                                                                     *
**********************************************************************/

(defun abFilterByValue (wave min max)
  (cond
    ((drIsWaveform wave)
     (let (xVec yVec newXVec newYVec val len newWave)
       (setq xVec (drGetWaveformXVec wave))
       (setq yVec (drGetWaveformYVec wave))
       (setq len (drVectorLength xVec))
       (setq newXVec (drCreateVec (drType xVec) len))
       (setq newYVec (drCreateVec (drType yVec) len))
       (for i 0 (sub1 len)
            (setq val (drGetElem yVec i))
            (when (and
                    (or (null max) (leqp val max))
                    (or (null min) (geqp val min)))
              (drAddElem newXVec (drGetElem xVec i))
              (drAddElem newYVec val)
              )
            )
       ;-----------------------------------------------------------------
       ; Set the units, name and expression attributes
       ;-----------------------------------------------------------------
       (putpropq newXVec (getq xVec units) units)
       (putpropq newXVec (getq xVec name) name)
       (putpropq newYVec (getq yVec units) units)
       (putpropq newYVec (getq yVec name) name)
       (setq newWave (drCreateWaveform newXVec newYVec))
       (famSetExpr newWave `(abFilterByValue ,(famGetExpr wave) ,min ,max))
       newWave
       )
     )
    ((famIsFamily wave)
     (famMap 'abFilterByValue wave min max)
     )
    (t
      (error "abFilterByValue: cannot handle %L\n" wave)
      )
    )
  )

Thanks a lot Andrew. This script works well.

Regards,

Vinay.