Plotting the DC sweep but clipped

The clip function only works with monotonic x vectors - which is not the case here. I wrote a function a while ago to filter (rather than clip) based on the y-values; I just extended it to work with x-values as well:

/* abFilterByValue.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Feb 02, 2015 
Modified   Sep 01, 2016 
By         A.D.Beckett

Filter outliers from a waveform (by value). Useful for histogram
plotting. For example:

abFilterByValue((statGetWaveform "Current_C3_0" nil ?resDbFile 
    axlGetHistoryResults(axlGetCurrentHistory(_vivaGetSessionName())) ?testName "AC" ?filtPointsList "") 
    8.29m 8.295m
)

Added support in 1.2 for filtering based on the x-value as a means to "clip"
signals with non-monotonic x-axes such as those from the dc hysteresis analysis 
in spectre

***************************************************

SCCS Info: @(#) abFilterByValue.il 09/01/16.10:35:59 1.2

*/

/**********************************************************************
*                                                                     *
*                   (abFilterByValue wave min max)                    *
*                                                                     *
* Filter a waveform by value. If any points are outside the range min *
*         to max, they are omitted from the output waveform.          *
*                                                                     *
**********************************************************************/

(defun abFilterByValue (wave min max @optional filterX)
  (cond
    ((drIsWaveform wave)
     (let (xVec yVec newXVec newYVec xval yval val len newWave)
       (setq xVec (drGetWaveformXVec wave))
       (setq yVec (drGetWaveformYVec wave))
       (setq len (drVectorLength xVec))
       (setq newXVec (drCreateVec (drType xVec) len))
       (setq newYVec (drCreateVec (drType yVec) len))
       (for i 0 (sub1 len)
            (setq xval (drGetElem xVec i))
            (setq yval (drGetElem yVec i))
            (setq val (if filterX xval yval))
            (when (and
                    (or (null max) (leqp val max))
                    (or (null min) (geqp val min)))
              (drAddElem newXVec xval)
              (drAddElem newYVec yval)
              )
            )
       ;-----------------------------------------------------------------
       ; Set the units, name and expression attributes
       ;-----------------------------------------------------------------
       (putpropq newXVec (getq xVec units) units)
       (putpropq newXVec (getq xVec name) name)
       (putpropq newYVec (getq yVec units) units)
       (putpropq newYVec (getq yVec name) name)
       (setq newWave (drCreateWaveform newXVec newYVec))
       (famSetExpr newWave `(abFilterByValue ,(famGetExpr wave) ,min ,max))
       newWave
       )
     )
    ((famIsFamily wave)
     (famMap 'abFilterByValue wave min max filterX)
     )
    (t
      (error "abFilterByValue: cannot handle %L\n" wave)
      )
    )
  )

The idea is that you can then do:

abFilterByValue(yourWaveform minX maxX t)

The t tells it to filter based on x rather than y values. Note that it filters rather than clips (so no interpolation at the ends - it simply omits any points outside the range).

Regards,

Andrew.