Define libraries as read-only

You can't do this in the cds.lib  but with a bit of SKILL code you can create a trigger that a achieves the same thing. This code below (keep the .ils suffix because it relies on SKILL++ lexical scoping) can do this - the comments at the top explain how to use this:

/* abReadOnlyLibs.ils

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jan 20, 2020 
Modified   
By         

Registers a list of libraries to be readonly in this session:

abReadOnlyLibs(list("mylib" "yourlib"))

If you need to make them editable again, you can do:

abReadOnlyLibs(nil ?reset t)

or

abReadOnlyLibs(list("newlib") ?reset t)

***************************************************

SCCS Info: @(#) abReadOnlyLibs.ils 01/20/20.11:37:49 1.1

*/


let((readOnlyLibs)
    /**********************************************************************
    *                                                                     *
    *                abReadOnlyLibs(listOfLibs @key reset)                *
    *                                                                     *
    * Register a list of libraries to be readonly. If ?reset t is passed, *
    *       it forgets any previously registered readonly libraries       *
    *                                                                     *
    **********************************************************************/
    globalProc(abReadOnlyLibs(listOfLibs @key reset)
        when(reset || !readOnlyLibs
            readOnlyLibs=makeTable('readOnlyLibs t)
        )
        foreach(libName listOfLibs
            readOnlyLibs[libName]=nil
        )
        ddRegTrigger("PreAutoCheckOut" 'abReadOnlyLibsPreAutoCheckOut 1)
        t
    )

    /***********************************************************************
    *                                                                      *
    *      abReadOnlyLibsPreAutoCheckOut(@optional objList _isBatch)       *
    *                                                                      *
    * Trigger which does the work to check whether you are allowed to edit *
    *                          the object or not                           *
    *                                                                      *
    ***********************************************************************/
    globalProc(abReadOnlyLibsPreAutoCheckOut(@optional objList _isBatch)
        foreach(mapcar obj objList
            readOnlyLibs[obj->lib->name]
        )
    )
)

Too bad that there is no"non-scripting" way.

I will try when I find some time.

HoWei said:

Too bad that there is no"non-scripting" way

There might be a way with your revision control system too. The code above is not very complicated, and certainly a reasonable approach for something a little non-standard. This is one of the reasons why we have a powerful programming capability with SKILL in Virtuoso!

Andrew.

Yes, that is another option, but unfortunately (as we have setup our revision control environment), we can only lock complete "referenced project", but not single libs within these "referenced projects". Of course there are also ways that include scripting (pre-chkout-triggers and so on) to achieve it - but its not very handy for designers.

There are option and we have to find the way that matches best to our environment.