Getting/highlighting all input pins of a design in schematic

Sunny,

You could use this code:

procedure(CCFselectPinsByDir(@key (cellView geGetEditCellView()) 
    (direction "input"))
  foreach(term cellView~>terminals
    when(term~>direction==direction
      foreach(pin term~>pins
        foreach(fig pin~>figs
          geSelectFig(fig)
        )
      )
    )
  )
  t
)

If you just call CCFselectPinsByDir() it will select all input pins; if you use CCFselectPinsByDir(?direction "output") it will select all output pins. You can then see the names in the navigator (note, this will add to the selection, so you may want to deselect everything first), or you can list their names by doing:

geGetSelSet()~>pin~>term~>name

Andrew

Thanks Andrew! This was very helpful. Any way this selection of input terminals could also show up on the symbol for the schematic? I tried this code on the schematic and it works, but if I come one level up from the schematic and see it as a symbol, there is no selection made there. I assume this is happening because the symbol does not have actual pins and this code is meant for cellviews with actual pins. I tried playing around with the code and modifying it to see if I can get it working for the symbol too, but couldn't do so.

Tried something like the code below but it seems that instance terminals do not have figs as their attributes.

procedure(CCFselectPinsByDir(@key (cellView geGetEditCellView()) 
    (direction "input"))
  foreach(inst cellView~>instances
    foreach(term inst~>instTerms
      when(term~>direction==direction
        foreach(fig term~>figs
            geSelectFig(fig)
        )
      )
    )
  )
  t
)

You can't select instance pins using geSelectFig since they are not level-0 objects (i.e. shapes or instances within the schematic directly). They live within the master that of the symbol that is instantiated. So your code wouldn't work for two reasons - one there are no figs on the term object, and secondly, geSelectFig wouldn't have been able to select them anyway.

This code would work however:

procedure(CCFselectInstPinsByDir(@key (cellView geGetEditCellView()) 
    (direction "input"))
  foreach(inst cellView~>instances
    foreach(instTerm inst~>instTerms
      when(instTerm~>direction==direction
        foreach(pin instTerm~>term~>pins
          foreach(fig pin~>figs
            geSelectObject(fig list(list(inst 1 0 0)))
          )
        )
      )
    )
  )
  t
)

Note that to see the results of the selection, geGetSelSet() won't help - you'd need to use geGetObjectSelectedSet() instead. This also depends on you having "pin" checked in the instance objects part of Edit->Select->Filter - otherwise you're not allowed to select the lower level shape.

You can also use hsmGetSelectedSet() to get a different representation fo the hierarchical selections.

Regards,

Andrew.