Is it possible to hide instances?

No, this is not possible.

Is it possible to do something with skill code like using the bBox of the original schematic and assign a key combo, so when that key combo is pressed it only fit that part of that schematic

One approach would be to use Create->Note-Shape, pick "rectangle" as the shape type and draw a box in the region you want to zoom to. Then load this code that I just wrote as an example:

/* abZoomToTextLayer.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jul 13, 2022 
Modified   
By         

Allow you to draw a box (using Create->Note->Shape) on the schematic, and then
you can use this function to zoom to fit all such note shapes

***************************************************

SCCS Info: @(#) abZoomToTextLayer.il 07/13/22.15:59:26 1.1

*/

/************************************************************************
*                                                                       *
* abZoomToTextLayer(@optional (win hiGetCurrentWindow()) (enlarge 1.1)) *
*                                                                       *
*           Zoom to fit the drawn text layer on a schematic.            *
*                                                                       *
************************************************************************/

procedure(abZoomToTextLayer(@optional (win hiGetCurrentWindow()) (enlarge 1.1))
  let((textLP bBox (cv geGetEditCellView(win)))
    textLP=car(exists(LP cv~>lpps LP~>layerName=="text" && LP~>purpose=="drawing"))
    ;--------------------------------------------------------------------
    ; Find the overall bounding box of the text layer (if present) or the 
    ; whole cellView otherwise, and enlarge by the factor given (to add the usual
    ; 10% margin around the outside)
    ;--------------------------------------------------------------------
    bBox=
      if(textLP~>shapes then
        destructuringBind(((ollx olly) (ourx oury)) car(textLP~>shapes)~>bBox
          foreach(shape cdr(textLP~>shapes)
            destructuringBind(((llx lly) (urx ury)) shape~>bBox
              ollx=min(ollx llx)
              olly=min(olly lly)
              ourx=max(ourx urx)
              oury=max(oury ury)
            )
          )
          list(ollx*enlarge:olly*enlarge ourx*enlarge:oury*enlarge)
        )
      else
        destructuringBind(((ollx olly) (ourx oury)) cv~>bBox
          list(ollx*enlarge:olly*enlarge ourx*enlarge:oury*enlarge)
        )
      )
    hiZoomIn(win bBox)
  )
)

and you could then put abZoomToTextLayer() on a bindkey. If you call the function, it will zoom to the overall bounding box of the text layer (the layer used for notes in the schematic editor) and if not present it will zoom to the whole cellView.

Andrew

One approach would be to use Create->Note-Shape, pick "rectangle" as the shape type and draw a box in the region you want to zoom to. Then load this code that I just wrote as an example:

/* abZoomToTextLayer.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jul 13, 2022 
Modified   
By         

Allow you to draw a box (using Create->Note->Shape) on the schematic, and then
you can use this function to zoom to fit all such note shapes

***************************************************

SCCS Info: @(#) abZoomToTextLayer.il 07/13/22.15:59:26 1.1

*/

/************************************************************************
*                                                                       *
* abZoomToTextLayer(@optional (win hiGetCurrentWindow()) (enlarge 1.1)) *
*                                                                       *
*           Zoom to fit the drawn text layer on a schematic.            *
*                                                                       *
************************************************************************/

procedure(abZoomToTextLayer(@optional (win hiGetCurrentWindow()) (enlarge 1.1))
  let((textLP bBox (cv geGetEditCellView(win)))
    textLP=car(exists(LP cv~>lpps LP~>layerName=="text" && LP~>purpose=="drawing"))
    ;--------------------------------------------------------------------
    ; Find the overall bounding box of the text layer (if present) or the 
    ; whole cellView otherwise, and enlarge by the factor given (to add the usual
    ; 10% margin around the outside)
    ;--------------------------------------------------------------------
    bBox=
      if(textLP~>shapes then
        destructuringBind(((ollx olly) (ourx oury)) car(textLP~>shapes)~>bBox
          foreach(shape cdr(textLP~>shapes)
            destructuringBind(((llx lly) (urx ury)) shape~>bBox
              ollx=min(ollx llx)
              olly=min(olly lly)
              ourx=max(ourx urx)
              oury=max(oury ury)
            )
          )
          list(ollx*enlarge:olly*enlarge ourx*enlarge:oury*enlarge)
        )
      else
        destructuringBind(((ollx olly) (ourx oury)) cv~>bBox
          list(ollx*enlarge:olly*enlarge ourx*enlarge:oury*enlarge)
        )
      )
    hiZoomIn(win bBox)
  )
)

and you could then put abZoomToTextLayer() on a bindkey. If you call the function, it will zoom to the overall bounding box of the text layer (the layer used for notes in the schematic editor) and if not present it will zoom to the whole cellView.

Andrew