Results Display Window

Dear shaarawy2023,

shaarawy2023 said:

how to show specific parameter in the Results Display Window instead of showing all the parameter (i.e. i want to display only cgs, region, gm, id and vds)

If you are only interested in the four parameters you indicate, is there a speciifc reason you do not want to define these operating point parameters as distinct outputs in order that you can print or view them after a simulation? There are a number of ways to do this in ADE Explorer/Assembler. Fro example, there is a video at URL:

https://support.cadence.com/apex/ArticleAttachmentPortal?id=a1O3w000009yCkQEAU

and a companion Troubleshooting article at URL:

https://support.cadence.com/apex/ArticleAttachmentPortal?id=a1Od0000000urgbEAA&pageName=ArticleContent&id=a1Od0000000urgbEAA&oMenu=Documents%20which%20may%20be%20similar%20to%20this%20document

You could also just print all the parameters to an external file and use UNIX tools (awk, sed, grep) to filter the file. To print the operating points to a file, please see the last section of the Cadence presentation at URL:

https://support.cadence.com/apex/ArticleAttachmentPortal?id=a1O0V0000090teVUAQ&pageName=ArticleContent

I hope this helps shaarawy2023!

Shawn

Further to Shawn's suggestions, it's not really possible to directly do this via the Results Display Window, but with a bit of SKILL code you can do with provided you don't mind manually editing an expression.

First of all, put the code below in a file (e.g. abOP.il) and then load in the CIW or .cdsinit: load("abOP.il")

Then use Results→Print→DC Operating Points and select the instance you want. You'll get all of the parameters shown in the window. 

Next in the Results Display Window, use Expressions→Edit and select the entry with the expression - for example:

OP("/I7/M1" "??")

and change this to:

abOP("/I7/M1" "cgs" "region" "gm" "id" "vds")

Press the "change" button, and then you should get:

Here's the SKILL code:

/* abOP.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jul 30, 2022 
Modified   
By         

Produce an output similar to OP(instName "??") but with a specified
list of parameters only, rather than all. Useful with ocnPrint
or the results print window in ADE

abOP("/I7/M1" "gm" "gds" "id" "ids")

***************************************************

SCCS Info: @(#) abOP.il 07/30/22.17:43:44 1.1

*/

/***************************************************************
*                                                              *
*                 abOP(instName @rest params)                  *
*                                                              *
*  Similar to OP() except can give multiple parameter names.   *
*   Returns an output similar to OP(instName "??") but with    *
*       only the specified subset of parameters included       *
*                                                              *
***************************************************************/

procedure(abOP(instName @rest params)
  unless(params params=list("??"))
  ; cope with a list of parameters being passed or multiple individual 
  ; arguments
  params=foreach(mapcan param params
    if(listp(param) then
      copy(param)
    else
      list(param)
    )
  )
  cond(
    ;--------------------------------------------------------------------
    ; If an instance name is passed, call OP with all parameters and
    ; then recursively call this function with the resulting waveform
    ;--------------------------------------------------------------------
    (stringp(instName)
      let((wave)
        if(car(params)=="??" then
          OP(instName "??")
        else
          wave=abOP(OP(instName "??") params)
          famSetExpr(wave `abOP(,instName ,@params))
          wave
        )
      )
    )
    ;--------------------------------------------------------------------
    ; If a waveform, then filter out just the matching parameter
    ; names - creating a new waveform
    ;--------------------------------------------------------------------
    (drIsWaveform(instName)
      let(((paramTable makeTable('paramTable nil))
          xVec yVec newXVec newYVec len)
        foreach(param params
          paramTable[param]=t
        )
        xVec=drGetWaveformXVec(instName)
        yVec=drGetWaveformYVec(instName)
        newXVec=drCreateVec(drType(xVec) length(paramTable))
        newYVec=drCreateVec(drType(yVec) length(paramTable))
        len=drVectorLength(xVec)
        for(i 0 len-1
          when(paramTable[drGetElem(xVec i)]
            drAddElem(newXVec drGetElem(xVec i))
            drAddElem(newYVec drGetElem(yVec i))
          )
        )
        drCreateWaveform(newXVec newYVec)
      )
    )
    ;--------------------------------------------------------------------
    ; Handle swept data
    ;--------------------------------------------------------------------
    (famIsFamily(instName)
      famMap('abOP instName params)
    )
    (t
      error("abOP: can't handle %L\n" instName)
    )
  )
)

Regards,

Andrew

Further to Shawn's suggestions, it's not really possible to directly do this via the Results Display Window, but with a bit of SKILL code you can do with provided you don't mind manually editing an expression.

First of all, put the code below in a file (e.g. abOP.il) and then load in the CIW or .cdsinit: load("abOP.il")

Then use Results→Print→DC Operating Points and select the instance you want. You'll get all of the parameters shown in the window. 

Next in the Results Display Window, use Expressions→Edit and select the entry with the expression - for example:

OP("/I7/M1" "??")

and change this to:

abOP("/I7/M1" "cgs" "region" "gm" "id" "vds")

Press the "change" button, and then you should get:

Here's the SKILL code:

/* abOP.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Jul 30, 2022 
Modified   
By         

Produce an output similar to OP(instName "??") but with a specified
list of parameters only, rather than all. Useful with ocnPrint
or the results print window in ADE

abOP("/I7/M1" "gm" "gds" "id" "ids")

***************************************************

SCCS Info: @(#) abOP.il 07/30/22.17:43:44 1.1

*/

/***************************************************************
*                                                              *
*                 abOP(instName @rest params)                  *
*                                                              *
*  Similar to OP() except can give multiple parameter names.   *
*   Returns an output similar to OP(instName "??") but with    *
*       only the specified subset of parameters included       *
*                                                              *
***************************************************************/

procedure(abOP(instName @rest params)
  unless(params params=list("??"))
  ; cope with a list of parameters being passed or multiple individual 
  ; arguments
  params=foreach(mapcan param params
    if(listp(param) then
      copy(param)
    else
      list(param)
    )
  )
  cond(
    ;--------------------------------------------------------------------
    ; If an instance name is passed, call OP with all parameters and
    ; then recursively call this function with the resulting waveform
    ;--------------------------------------------------------------------
    (stringp(instName)
      let((wave)
        if(car(params)=="??" then
          OP(instName "??")
        else
          wave=abOP(OP(instName "??") params)
          famSetExpr(wave `abOP(,instName ,@params))
          wave
        )
      )
    )
    ;--------------------------------------------------------------------
    ; If a waveform, then filter out just the matching parameter
    ; names - creating a new waveform
    ;--------------------------------------------------------------------
    (drIsWaveform(instName)
      let(((paramTable makeTable('paramTable nil))
          xVec yVec newXVec newYVec len)
        foreach(param params
          paramTable[param]=t
        )
        xVec=drGetWaveformXVec(instName)
        yVec=drGetWaveformYVec(instName)
        newXVec=drCreateVec(drType(xVec) length(paramTable))
        newYVec=drCreateVec(drType(yVec) length(paramTable))
        len=drVectorLength(xVec)
        for(i 0 len-1
          when(paramTable[drGetElem(xVec i)]
            drAddElem(newXVec drGetElem(xVec i))
            drAddElem(newYVec drGetElem(yVec i))
          )
        )
        drCreateWaveform(newXVec newYVec)
      )
    )
    ;--------------------------------------------------------------------
    ; Handle swept data
    ;--------------------------------------------------------------------
    (famIsFamily(instName)
      famMap('abOP instName params)
    )
    (t
      error("abOP: can't handle %L\n" instName)
    )
  )
)

Regards,

Andrew

The initial argument check

if( listp(param) then
  copy(param)
else
  list(param)
)

could be extended with e.g.

cond(
  (listp(param)    copy(param))
  (stringp(param)  parseString(param))
  (t               list(param))
)


so you could additionally give all the parameters as single string e.g. abOP("/I7/M1" "cgs region gm id vds"), which might get usefull under certain circumstances.

Regards,