Can I display connections for a node?

Dear Ichiro

maybe this article on support.cadence.com can help you.

Regards,

Matthias

Thanks for pointing that out Matthias. I was going to suggest an alternative approach, using Options->Display->Dynamic Net Highlighting which will dynamically highlight all connections on the net you hover over - also available via View->Net Highlighting. This can be enabled with SKILL:

envSetVal("schematic" "schDynamicNetHilightOn" 'boolean t)

Andrew

Hi Matthias,

That's the answer I was looking for !! I'll try to the skill code.

Thanks!

Ichiro

Hi Andrew,

Thanks for practical idea. I'll use it if I can not work the Matthias idea well.

Thanks,

Ichiro

Hi Matthias,

I saved the script as "FL.il" to current directory run Virtuso. In CIW, I typed "load("./FL.il") and enter key. Then returned below.

load("FL.il")
function CCSAddFlightProbeAll redefined
function CCSAddFlightProbeSelected redefined
function CCSDeleteFlightProbesSelected redefined
function CCSDeleteAllFlightProbes redefined
t.

But "Shift + any key(9 or 0 or 8 or 1)" can't work well..

Do you have any idea?

Regards,

Ichiro

Dear Ichiro,

i just tested it on my setup and the bindkeys do not work there either (I don't have time to investigate that on my own).
I tried replacing "Shift" with "Ctrl" - that worked for me. 

Regards

Matthias  

The best thing to do is to look at the key sequence you'd get if trying to add a bindkey via Options->Bindkeys. For example, for me shift-8 gives:

<Key>*

and shift-9 is 

<Key>)

This changed a while back (after the article was written, I believe). I thought there was an article specifically talking about that, but I couldn't find it...

Andrew

Hi Matthias and Andrew,

Finally, I was able to get it to work!!
It required redefinition to reserved bind keys, not assignment to free keys.

Can the color be changed every creating flightline ? I could realize with "random(9)"...

Regards,

Ichiro

I made a small change to cycle through colors - see the attached (this has redefined bindkeys which should work, at least on my keyboard; you may want to change the keys used to suit your needs):

/*************************************************************************
 * DISCLAIMER: The following code is provided for Cadence customers       *
 * to use at their own risk. The code may require modification to         *
 * satisfy the requirements of any user. The code and any modifications   *
 * to the code may not be compatible with current or future versions of   *
 * Cadence products. THE CODE IS PROVIDED "AS IS" AND WITH NO WARRANTIES, *
 * INCLUDING WITHOUT LIMITATION ANY EXPRESS WARRANTIES OR IMPLIED         *
 * WARRANTIES OF MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.         *
 *************************************************************************/

procedure(CCSAddFlightProbeAll()
  let( (win cv)
  
  win=hiGetCurrentWindow()
  cv=geGetWindowCellView(win)
  ; cycle through colors
  CCSAddFlightProbe.color=mod(((CCSAddFlightProbe.color)||8)+1,10)
  foreach(netname cv~>nets~>name   
        geMakeProbeWithColor(?window win 
             ?color list(lsprintf("y%d" CCSAddFlightProbe.color) "drawing") 
             ?object list(netname)
             ?probeType "net" 
             ?displayStyle "flight")
    ) ; foreach
  ) ; let
) ; procedure

hiSetBindKey("Schematics" "<Key>(" "CCSAddFlightProbeAll()")


procedure(CCSAddFlightProbeSelected()
  let( (win)
  
  win=hiGetCurrentWindow()
  ; cycle through colors
  CCSAddFlightProbe.color=mod(((CCSAddFlightProbe.color)||8)+1,10)
  foreach(netname cadr(cadr(car(hsmGetSelectedSet(?type 'net))))  
        geMakeProbeWithColor(?window win 
             ?color list(lsprintf("y%d" CCSAddFlightProbe.color) "drawing") 
             ?object list(netname)
             ?probeType "net" 
             ?displayStyle "flight")
    ) ; foreach
    
  ) ; let
) ; procedure

hiSetBindKey("Schematics" "<Key>*" "CCSAddFlightProbeSelected()")

procedure(CCSDeleteFlightProbesSelected()
let((win probeList SelectedNets)

win=hiGetCurrentWindow()
probeList=geGetAllProbe()
SelectedNets=cadr(cadr(car(hsmGetSelectedSet(?type 'net))))

foreach(probe probeList
	when(member(probe~>pathObjectName SelectedNets) 
	geDeleteProbe(win probe)
	); when
); foreach

);let
); procedure CCSDeleteFlightProbes

hiSetBindKey("Schematics" "<Key>!" "CCSDeleteFlightProbesSelected()")

procedure(CCSDeleteAllFlightProbes() 
let((win probeList) 

win=hiGetCurrentWindow() 
probeList=geGetAllProbe() 

foreach(probe probeList 
   geDeleteProbe(win probe) 
); foreach 

);let 
); procedure CCSDeleteAllFlightProbes 
hiSetBindKey("Schematics" "<Key>)" "CCSDeleteAllFlightProbes()")

Oh! That's perfect answer for my what I want.

Thank you Andrew!

Ichiro