viva env variable to control the trace name in the legend

I assume you have a "Config" sweep variable defined? I assume you have the legend set to "above" (under Graph->Properties and then the Graph Options tab)?

I'm not sure it's currently possible to change the default trace naming convention (I did some quick checks), but there are at least some requests for customising this. I just wanted to check that this is indeed what you are doing?

It's probably best to contact customer support (use the Case menu to submit a support case after logging in) to follow up on this.

Andrew 

yes and yes.

you are correct. that is what exactly I am doing.

I can manually change the trace name...but would like to automate this, if there is a way available.

Yes, that should be possible (what I don't think is possible is to have a default naming convention that covers this). I'll write something during this afternoon.

Andrew

If you load this code:

/* abRenameConfigTraces.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date        
Modified   
By         

Renames the traces in the current ViVA window to change any part which is
of the form CONFIG/libName/cellName=viewName to just viewName.

***************************************************

SCCS Info: @(#) abRenameConfigTraces.il 12/01/25.14:58:08 1.1

*/

/***************************************************************************
*                                                                          *
*                 abRenameConfigTraces([wid [subwindow]])                  *
*                                                                          *
* All trace names with CONFIG sweep variables in, leave just the view name *
*                 in the trace suffix to make it shorter.                  *
*                                                                          *
***************************************************************************/

procedure(abRenameConfigTraces(@optional (wid awvGetCurrentWindow()) subwindow)
  ;----------------------------------------------------------------------
  ; The pattern here defines the part to remove in the trace name
  ;----------------------------------------------------------------------
  let((currentNames (configPat pcreCompile("CONFIG/[^/]*/[^=]*=")))
    cond(
      (fixp(subwindow) subwindow=list(subwindow))
      (!subwindow subwindow=awvGetSubwindowList(wid))
    )
    ;--------------------------------------------------------------------
    ; Get the names for each subwindow, and then process them to remove the part
    ; matched in the pattern, then set the names back again
    ;--------------------------------------------------------------------
    foreach(subwin subwindow
      currentNames=awvGetWaveNameList(wid ?subwindow subwin)
      currentNames=list(
        car(currentNames)
        foreach(mapcar name cadr(currentNames)
          pcreReplace(configPat name "" 1)
        )
      )
      awvSetWaveNameList(currentNames wid)
    )
    t
  )
)

Then you can call abRenameConfigTraces() with the ViVA window you want to update as current, it will shorten all the CONFIG parts of the signal names in all sub windows (by default).

Andrew

If you load this code:

/* abRenameConfigTraces.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date        
Modified   
By         

Renames the traces in the current ViVA window to change any part which is
of the form CONFIG/libName/cellName=viewName to just viewName.

***************************************************

SCCS Info: @(#) abRenameConfigTraces.il 12/01/25.14:58:08 1.1

*/

/***************************************************************************
*                                                                          *
*                 abRenameConfigTraces([wid [subwindow]])                  *
*                                                                          *
* All trace names with CONFIG sweep variables in, leave just the view name *
*                 in the trace suffix to make it shorter.                  *
*                                                                          *
***************************************************************************/

procedure(abRenameConfigTraces(@optional (wid awvGetCurrentWindow()) subwindow)
  ;----------------------------------------------------------------------
  ; The pattern here defines the part to remove in the trace name
  ;----------------------------------------------------------------------
  let((currentNames (configPat pcreCompile("CONFIG/[^/]*/[^=]*=")))
    cond(
      (fixp(subwindow) subwindow=list(subwindow))
      (!subwindow subwindow=awvGetSubwindowList(wid))
    )
    ;--------------------------------------------------------------------
    ; Get the names for each subwindow, and then process them to remove the part
    ; matched in the pattern, then set the names back again
    ;--------------------------------------------------------------------
    foreach(subwin subwindow
      currentNames=awvGetWaveNameList(wid ?subwindow subwin)
      currentNames=list(
        car(currentNames)
        foreach(mapcar name cadr(currentNames)
          pcreReplace(configPat name "" 1)
        )
      )
      awvSetWaveNameList(currentNames wid)
    )
    t
  )
)

Then you can call abRenameConfigTraces() with the ViVA window you want to update as current, it will shorten all the CONFIG parts of the signal names in all sub windows (by default).

Andrew

This solution works amazingly! Thank you, as always!

If there is a way to automatically execute the script after every simulation, it would be better.

btw, I tried to put it in output expression, it does not work, so does not as well the expression for saving picture saveGraphImage which worked in ADE L.

Adding it as an output expression wouldn't help, because the graph has to have been plotted - and (normal) output expressions are evaluated in the expression evaluator process (or ICRP if using ICRP). Even the "all" output type wouldn't necessarily work.

You could define a bindkey to call the function so you can easily press it after plotting.

I did have some code which might help here in this article: How to set up and execute a Post Run Simulation OCEAN Script for ADE XL, Explorer, and Assembler simulations. Note, I didn't try it for this purpose though...

Andrew