skill code to place all layout cells in a Virtuoso lib to top level cell

/* CCFplaceAllInstances.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Dec 01, 2017 
Modified   
By         

Place an instance of each layout in a library into a cellView

examples 

CCFplaceAllInstances(?libName "stdcellLib" ?viewName "layout" ?columns 20
   ?spacing 2.0)
CCFplaceAllInstances(?cv cvId ?libName "stdcellLib" ?spacing 4.0)

***************************************************

SCCS Info: @(#) CCFplaceAllInstances.il 12/01/17.06:33:20 1.1

*/

/***************************************************************
*                                                              *
*      CCFplaceAllInstances(@key (cv geGetEditCellView())      *
*         libName viewName (spacing 5.0) (columns 10))         *
*                                                              *
*    Place an instance of every layout from library libName    *
*  with view viewName (or if viewName not specified, pick all  *
*   maskLayout view types from the library) in rows with up    *
* to columns instances per row. Additional spacing (specified  *
*    by the ?spacing argument) is added between instances.     *
*                                                              *
***************************************************************/

procedure(CCFplaceAllInstances(@key (cv geGetEditCellView()) 
    libName viewName (spacing 10.0) (columns 10))
  let((master masterDdId (x 0.0) (y 0.0) maxY width height (column 0))
    ;--------------------------------------------------------------------
    ; Iterate over all cells and views in the library, and either pick the
    ; matching viewName or views with type maskLayout
    ;--------------------------------------------------------------------
    foreach(cell ddGetObj(libName)->cells
      foreach(view cell->views
        master=nil
        if(viewName then
          when(view->name==viewName
            master=dbOpenCellViewByType(libName cell->name viewName)
          )
        else
          masterDdId=ddGetObj(libName cell->name view->name "*")
          when(masterDdId && ddMapGetFileViewType(masterDdId)=="maskLayout"
            master=dbOpenCellViewByType(libName cell->name view->name)
          )
        )
        when(master
          ;--------------------------------------------------------------
          ; Place instance, and then increment position based on size of
          ; the instance placed
          ;--------------------------------------------------------------
          destructuringBind(((llx lly) (urx ury)) master~>bBox
            width=urx-llx
            height=ury-lly
            maxY=if(maxY max(maxY height) height)
            dbCreateInst(cv master "" x-llx:y-lly "R0")
            column=mod(column+1 columns)
            if(zerop(column) then
              x=0.0
              y=y+maxY+spacing
              maxY=nil
            else
              x=x+width+spacing
            )
            dbClose(master)
          )
        )
      )
    )
    t
  )
)

I am seeing following ERROR when i run the command 

CCFplaceAllInstances(?libName "work_test" ?viewName "layout" ?columns 20 ?spacing 2)

*Error* dbCreateInst: argument #1 should be a database object (type template = "ddgltxg") - nil

You either need to run it with a layout window open and the current window (which is not the case for you, because otherwise the ?cv argument to the function would have had the default value of geGetEditCellView() - if that is returning nil, it means there is no current window for it to place the instances into), or you need to pass ?cv cvId where cvId is the database id of the cellView you're trying to place the instances into.

If you're trying to do this from batch (without any windows open),  you'd do:

cvId=dbOpenCellViewByType("mylib" "allCells" "layout" "maskLayout" "w")
CCFplaceAllInstances(?cv cvId ?libName "work_test" ?viewName "layout" ?columns 20 ?spacing 2)

Regards,

Andrew

Thanks @andrew..  for the quick response 

It worked with the layout opened 

To do in a batch mode .. Can you send me updated skill code with the updates 

Srikanth51 said:

To do in a batch mode .. Can you send me updated skill code with the updates

The code doesn't need updating. It works as-is (i.e. as posted back in 2017), and I gave an example of how to do this in batch mode in my last reply. The code was already designed to be used either with an interactive window, or a specified cellView id.

Andrew.

Srikanth51 said:

To do in a batch mode .. Can you send me updated skill code with the updates

The code doesn't need updating. It works as-is (i.e. as posted back in 2017), and I gave an example of how to do this in batch mode in my last reply. The code was already designed to be used either with an interactive window, or a specified cellView id.

Andrew.