How to copy selected objects from the current schematic window to other schematic window by using SKILL?

Hi Marben,

Do Check->Current CellView (typically the "x" bindkey) or File->Check and Save (typically shift-X) after doing the copy. 

The issue is that the cdsTerm labels on the transistor symbols can't display the nets because the nets do not get partially extracted after a copy using SKILL and the internal database has not been synchronised. So a better solution might be to change the code as follows (small change in abCopyToOtherWinCB):

/* abCopyToOtherWin.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Mar 06, 2013 
Modified   Dec 15, 2018 
By         A.D.Beckett

Put the copy on a bindkey, say:

hiSetBindKey("Layout" "<Key>F8" "abCopyToOtherWin()")

Copies selected objects from the current window to the window you click in when prompted

Updated in v1.2 to better handle schematics

***************************************************

SCCS Info: @(#) abCopyToOtherWin.il 12/15/18.11:45:19 1.2

*/

procedure(abCopyToOtherWinCB(srcWin _dont _points)
    let((destCv)
        ;----------------------------------------------------------------
        ; Since current window will be the destination window, this is correct
        ;----------------------------------------------------------------
        destCv=geGetWindowCellView()
        foreach(fig geGetSelSet(srcWin)
            ;------------------------------------------------------------
            ; Transformation is effectively null, since want the
            ; positions to be the same
            ;------------------------------------------------------------
            dbCopyFig(fig destCv list(0:0 "R0" 1))
        )
        ;----------------------------------------------------------------
        ; Sync the schematic internal database representations
        ;----------------------------------------------------------------
        when(destCv~>cellViewType=="schematic"
            schSync(list(destCv))
        )
        t
    )
)

procedure(abCopyToOtherWin(@optional (srcWin hiGetCurrentWindow()))
    unless(windowp(srcWin) error("Must have a valid window to start from"))
    hiSetCurrentWindow(srcWin)
    enterMultiRep(
        ?prompts '("Point to the source window" "Point to the destination window")
        ?points list(0:0)
        ?doneProc "abCopyToOtherWinCB"
        ?dontDraw t
    )
)

Regards,

Andrew

Hi Andrew,

It almost works.

All errors display in the copied window is gone.

There is only one more problem.

The pin net name is not copied.

There must be something like "VP", "a" , "y" . . .etc in the target schematic window to which selected objects is to be copied,

not " ipin", ipin" "opin" .

Best regards,

Marben

Hi Marben,

Whoops! I didn't notice that. Not surprising, because dbCopyFig is only going to copy the figure and not the pin. So I changed the code a little to use schCopy instead when it's a schematic, which should handle the more complex objects. This seems to work:

/* abCopyToOtherWin.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Mar 06, 2013 
Modified   Dec 15, 2018 
By         A.D.Beckett

Put the copy on a bindkey, say:

hiSetBindKey("Layout" "<Key>F8" "abCopyToOtherWin()")

Copies selected objects from the current window to the window you click in when prompted

Updated in v1.2 to better handle schematics. Did it properly in v1.3!

***************************************************

SCCS Info: @(#) abCopyToOtherWin.il 12/15/18.13:01:02 1.3

*/

procedure(abCopyToOtherWinCB(srcWin _dont _points)
    let((destCv isSch)
        ;----------------------------------------------------------------
        ; Since current window will be the destination window, this is correct
        ;----------------------------------------------------------------
        destCv=geGetWindowCellView()
        isSch=destCv~>cellViewType=="schematic"
        foreach(fig geGetSelSet(srcWin)
            ;------------------------------------------------------------
            ; Transformation is effectively null, since want the
            ; positions to be the same
            ;------------------------------------------------------------
            if(isSch then
                schCopy(fig destCv list(0:0 "R0" 1))
            else
                dbCopyFig(fig destCv list(0:0 "R0" 1))
            )
        )
        t
    )
)

procedure(abCopyToOtherWin(@optional (srcWin hiGetCurrentWindow()))
    unless(windowp(srcWin) error("Must have a valid window to start from"))
    hiSetCurrentWindow(srcWin)
    enterMultiRep(
        ?prompts '("Point to the source window" "Point to the destination window")
        ?points list(0:0)
        ?doneProc "abCopyToOtherWinCB"
        ?dontDraw t
    )
)

Regards,

Andrew.

Hi Andrew,

It is now working perfectly.

Thank you very much.

Schematic check completed with no errors.

Best regards,

Marben