Unable to create multiple pins in symbolview using skill

Hi Lavanya,

A few issues - the code was placing the pins at fixed locations (0:0 and 0:100) so all the input pins would have been on top of each other and the output pins on top of each other. If you'd fit the window having created the pins (in either "a" or "w") mode you'd have not seen anything because the pins were so far apart that they'd have been tiny dots on the screen. So it probably appeared to work because you opened the design when it was empty and so could see the origin - and hence only saw the pin at 0:0. 

The open mode (a or w) controls whether it throws everything away or not - so if you run the code several times with "a" mode you will just keep adding more pins. It certainly doesn't behave differently other than that.

Also, rather than using nth to look up the corresponding direction, it would be better to use a foreach loop with two loop variables to loop over the name and direction lists together. 

I rewrote the code to step the location of the input and output pins - see the improved version below:

cv=dbOpenCellViewByType("opamp090" "test_3" "symbol" "schematicSymbol" "w")

procedure(CCScreatePin( portList directionList  cv )
  let( (mysympin inY outY pinPitch) 
    mysympin = dbOpenCellViewByType("basic" "sympin" "symbol")
    inY=0.0
    outY=0.0
    pinPitch=0.125
    foreach((portName mytermdir) portList directionList
      let( (mypinfig)
        case(mytermdir
          ("input"
            mypinfig=schCreateSymbolPin(cv mysympin portName "input" 0:inY "R0")
            inY=inY+pinPitch
          )
          ("output"
            mypinfig=schCreateSymbolPin(cv mysympin portName "output" 1:outY "R0")
            outY=outY+pinPitch
          )
          (t
            error("Unexpected terminal direction\n")
          )
        );case
      ) ;let
    ) ;foreach
    dbSave(cv)
  );let
);procedure

CCScreatePin( '("IN" "IN2" "IN3" "OUT" "OUT2")  
  '("input" "input" "input" "output" "output")   cv)

Regards,

Andrew

Thanks Andrew

Thanks Andrew