Issue with a SKILL code o/p

Your unboundInst function returns the list of unbound instances (see the mylist variable at the end). You need that because it's a recursive function. This is then called as the last function in srFindUnboundInst, and so it's the return value of srFindUnboundInst. I suggest that you change the function to:

procedure(srFindUnboundInst()
  let((myLib myCell myview)

    myLib = geGetEditCellView()~>libName
    myCell = geGetEditCellView()~>cellName
    myview = geGetEditCellView()~>viewName

    unboundInst(myLib myCell myview)
    t
  )
)

I also added in a let to declare some local variables to avoid myLib, myCell and myview becoming global variables. This function would now return t, and so when the return value is displayed in the CIW, it won't display the list.

Regards,

Andrew.

Thanks a lot Andrew, this works.

Also, I've the o/p getting printed in the CIW, how can i print that in a pop-up window instead?

Thanks

Sooraj

Thanks a lot Andrew, this works.

Also, I've the o/p getting printed in the CIW, how can i print that in a pop-up window instead?

Thanks

Sooraj

I updated your code to be able to write to a temporary file, and then display that in the main function:

procedure(srFindUnboundInst()
  let((myLib myCell myview tempFile tempPort)

    tempFile = makeTempFileName("/tmp/missingInstances")
    tempPort = outfile(tempFile)
    myLib = geGetEditCellView()~>libName
    myCell = geGetEditCellView()~>cellName
    myview = geGetEditCellView()~>viewName

    unboundInst(myLib myCell myview tempPort)
    close(tempPort)
    when(fileLength(tempFile)>0
      view(tempFile nil "Unbound instances")
    )
    deleteFile(tempFile)
    t
  )
)

procedure(unboundInst(myLib myCell myview @optional (outport stdout) (mylist list()))
  let(( cv insts myMaster skipLibList)
    skipLibList=list("basic" "analogLib" "US_8ths")

    cv=dbOpenCellViewByType(myLib myCell myview "" "r")
    insts = cv~>instHeaders

    foreach( header insts
      myMaster= header~>master
      getWarn()

      if( myMaster then
        if( member( myview myMaster~>cell~>views~>name) && !member(myMaster mylist) && !member(header~>libName skipLibList) then
          mylist = cons( myMaster mylist)

          mylist=unboundInst(
            header~>libName 
            header~>cellName 
            if(cv~>cellViewType=="schematic" then myview else header~>viewName)
            outport
            mylist
          )
        )
      else
        fprintf(outport "Unbound Master: Library:%s, Cell:%s, View:%s, Missing From: Lib:%s, Cell:%s, View:%s\n"
          header~>libName header~>cellName header~>viewName cv~>libName cv~>cellName cv~>viewName
        )

      );if
    );foreach
    dbClose(cv)

    mylist

  );let
);procedure

This is exactly what i was expecting, it works like a charm!

Thank you so much Andrew.

Hi Andrew,

I do not understand the logic of "if" statement. Could you tell me the purpose of this line ?

mylist=unboundInst(
            header~>libName
            header~>cellName
            if(cv~>cellViewType=="schematic" then myview else header~>viewName)
            outport
            mylist
          )

Thanks,

ManChak

Hi ManChak,

That was in your code in the first place! I did not write it. 

Presumably it's there so that if you cellView you're in is a schematic type, then it switches into the same view name as the current view (probably "schematic"). So for layouts it would switch into the view name instantiated; for schematic hierarchies you don't want to switch into the symbol but the corresponding schematic.

However, as I said, this is not my code - it's yours...

Andrew.