get cell Names from Nested Category

There are two main issues:

1. You're using the memq function to check for strings in the sublist. You should never compare strings with eq (or memq) as odd things can happen. There's some caching of string objects to minimise duplication, but you cannot guarantee that eq/memq will see two identically-valued strings will be the same unless they originated from the same source. In practice, eq should only be used with symbols and lists (and again, with lists you know you're comparing pointers, not the values in the list). So this should use member() not memq(). I'd have probably used cadr(catMemberListItem)=="category" rather than member or memq. Because of the memq my first attempt to run your code did not recursively call categoryItem.
2. The other big problem is that you didn't put catTable in the let, so it's global - and the recursive call overwrites the catTable in the level above - hence your issue.

Here's the updated code. Note that you could also avoid assigning returnList because you never use it - the last line in the code could just be list( tableGlobal tableGlobal2 ) without the assignment. Similarly catNameTable is assigned to but never used.

procedure( categoryItem(dvId catName tableGlobal tableGlobal2)
    ; ANDREW - declare variables as local
    ; note that catNameTable and returnList are not really used (last statement doesn't need to
    ; be an assignment)
    let( (returnList catTable catNameTable catId catMemberList)
        catTable = makeTable(strcat(catName "Tbl"))
        catNameTable = makeTable(strcat(catName "Tb2"))
        catId = ddCatFindCat( dvId catName "r")
        catMemberList = ddCatGetCatMembers(catId)
        catTable["cellNameList"] = '()

        tableGlobal2[catName] = '();nil 
        foreach( catMemberListItem catMemberList
;	printf("DEBUG: %L\n" catMemberListItem)
	    ; ANDREW - DO NOT USE memq for comparing strings. Use member instead
            if( member("category" catMemberListItem) then
                categoryItem( dvId car(catMemberListItem) tableGlobal tableGlobal2)
                if( tableGlobal2[catName] then
                     setarray( tableGlobal2 catName cons(strcat(car(catMemberListItem) ) arrayref(tableGlobal2 catName)) )
                else
                     setarray( tableGlobal2 catName list(strcat(car(catMemberListItem) ) ) )
                ) 
           else
                setarray( catTable "cellNameList" cons( car(catMemberListItem) arrayref( catTable "cellNameList" ))) 
           )
       ) 
      printf( "catName %s catTable %s\n" catName catTable)
      tableGlobal[catName] = catTable
      returnList = list( tableGlobal tableGlobal2 ) 
     )
)
/*

dvId = ddGetObj("analogLib")
tableGlobal = makeTable("glbl")
tableGlobal2 = makeTable("glbl2")
abc = categoryItem( dvId "Sources" tableGlobal tableGlobal2)

*/

Regards,

Andrew.

There are two main issues:

1. You're using the memq function to check for strings in the sublist. You should never compare strings with eq (or memq) as odd things can happen. There's some caching of string objects to minimise duplication, but you cannot guarantee that eq/memq will see two identically-valued strings will be the same unless they originated from the same source. In practice, eq should only be used with symbols and lists (and again, with lists you know you're comparing pointers, not the values in the list). So this should use member() not memq(). I'd have probably used cadr(catMemberListItem)=="category" rather than member or memq. Because of the memq my first attempt to run your code did not recursively call categoryItem.
2. The other big problem is that you didn't put catTable in the let, so it's global - and the recursive call overwrites the catTable in the level above - hence your issue.

Here's the updated code. Note that you could also avoid assigning returnList because you never use it - the last line in the code could just be list( tableGlobal tableGlobal2 ) without the assignment. Similarly catNameTable is assigned to but never used.

procedure( categoryItem(dvId catName tableGlobal tableGlobal2)
    ; ANDREW - declare variables as local
    ; note that catNameTable and returnList are not really used (last statement doesn't need to
    ; be an assignment)
    let( (returnList catTable catNameTable catId catMemberList)
        catTable = makeTable(strcat(catName "Tbl"))
        catNameTable = makeTable(strcat(catName "Tb2"))
        catId = ddCatFindCat( dvId catName "r")
        catMemberList = ddCatGetCatMembers(catId)
        catTable["cellNameList"] = '()

        tableGlobal2[catName] = '();nil 
        foreach( catMemberListItem catMemberList
;	printf("DEBUG: %L\n" catMemberListItem)
	    ; ANDREW - DO NOT USE memq for comparing strings. Use member instead
            if( member("category" catMemberListItem) then
                categoryItem( dvId car(catMemberListItem) tableGlobal tableGlobal2)
                if( tableGlobal2[catName] then
                     setarray( tableGlobal2 catName cons(strcat(car(catMemberListItem) ) arrayref(tableGlobal2 catName)) )
                else
                     setarray( tableGlobal2 catName list(strcat(car(catMemberListItem) ) ) )
                ) 
           else
                setarray( catTable "cellNameList" cons( car(catMemberListItem) arrayref( catTable "cellNameList" ))) 
           )
       ) 
      printf( "catName %s catTable %s\n" catName catTable)
      tableGlobal[catName] = catTable
      returnList = list( tableGlobal tableGlobal2 ) 
     )
)
/*

dvId = ddGetObj("analogLib")
tableGlobal = makeTable("glbl")
tableGlobal2 = makeTable("glbl2")
abc = categoryItem( dvId "Sources" tableGlobal tableGlobal2)

*/

Regards,

Andrew.

Thanks Andrew!! Code is giving the correct output now..