SKILL to Identify a LABEL over an Instance

It works OK for me - note that you have to use a different approach in different branches of the code, and maybe because your close parentheses were a bit screwy (I fixed those too) - I suspect you may have inserted the code in the wrong place. Shows the benefit of clean and consistent indentation...

Note I didn't spend time formatting the output - I'll leave that to you (BTW, the layer was "Metal1" "label" in my case, so you'll need to fix that for your technology).

;; ANDREW passed in the file id as an argument (defaults to appearing in the CIW)
;; rather than having another global variable
procedure(HilightCellByArea(lib cell level @optional (myFileId poport))
  let((cv instList rect instBox overlapLabel foundFlag)
    ;; Deleting old highlights.To prevent uncomment the below line
    ;; ANDREW: using a global variable such as hset is a really bad idea as it's easy
    ;; to clash with somebody else's code. Note that this doesn't really delete the old
    ;; highlights either - it just  makes them invisible. I'd probably store the object as
    ;; a property on the window instead rather than making it global - if you are going
    ;; to make it global, use a prefix for the variable to make it unique
    when(boundp('hset) hset->enable=nil)
    cv=geGetWindowCellView()
    rect=enterBox(
      ?prompts list("Enter the first corner of your box."
      "Enter the last corner of your box.")
    )
    instList=dbGetOverlaps(cv rect nil level nil)
    ;; It uses hilite layer packet. You can change it to y0-y9 layer or any other hilite lpp
    ;;hset = geCreateHilightSet(cv list("y0" "drawing") nil)
    ;;hset = geCreateHilightSet(cv list("hilite" "drawing1") nil)
    hset = geCreateHilightSet(cv list("hilite" "drawing") nil)
    hset->enable = t
    foreach(instId instList
      if(listp(instId) then
        instBox=CCSTransformBBox(instId)
        instId=car(instBox)
        when(instId~>libName==lib && instId~>cellName==cell
          geAddHilightRectangle(hset cadr(instBox))
          fprintf(myFileId, "Highlighted the %L instance %L of hierarchy at:%L \n"
            cell buildString(append1(caddr(instBox)~>name instId~>name) "/") cadr(instBox)
          )
          foundFlag=t
          overlapLabel=dbGetTrueOverlaps(cv cadr(instBox) list("Metal1" "label"))
          fprintf(myFileId "LABEL FOUND: %L\n" overlapLabel~>theLabel)
        )
      else
        when(instId~>libName==lib && instId~>cellName==cell
          geAddHilightFig(hset instId)
          fprintf(myFileId, "Highlighted the %L instance %L of top cell at:%L \n"
            cell instId~>name instId~>bBox
          )
          foundFlag=t
          overlapLabel=dbGetTrueOverlaps(cv instId~>bBox list("Metal1" "label"))
          fprintf(myFileId "LABEL FOUND: %L\n" overlapLabel~>theLabel)
        )
      );if listp
    ) ;foreach
    t
  ) ;let
) ;procedure

procedure(CCSTransformBBox(inst)
  let((flatList y location)
    while(listp(inst)
      y = car(inst)
      flatList = append(flatList list(y))
      inst = cadr(inst) ; next inst
    );while
    location=dbTransformBBox(inst~>bBox dbGetHierPathTransform(list(flatList inst)))
    list(inst location flatList)
  );let
);procedure

Andrew, it seems like the code doesn't go down the hierarchy. It identifies the labels on the same level but if I put it few cells below, it doesn't find it.

I tried using some transformtions but it seems not working....

Thanks, 

Sorry, I didn't exhaustively test the code because I didn't entirely know what you wanted - and I was leaving it to you to correct for your precise needs. Because you're just using the output of dbGetOverlaps from the top level, you'd want to pass level as the dbGetTrueOverlaps calls used to find the labels. At the moment, no fourth argument is passed, and so it defaults to top level labels only. You'd then need to process the resulting lists to find the actual label object at the end - simplest is to call something like this on each result of the dbGetTrueOverlaps - since you're only trying to find the actual label text:

Using abGetHierPathShape from this code will help. You could then do (and I didn't test this):

foreach(overlapLabel dbGetTrueOverlaps(cv cadr(instBox) list("Metal1" "label") level)
  actualLabel=abGetHierPathShape(overlapLabel)
  when(actualLabel~>objType=="label"
    fprintf(myFileId "LABEL FOUND: %L\n" actualLabel~>theLabel)
  )
)

Thanks Andrew. It works great.

Danny

Thanks Andrew. It works great.

Danny