hiCreateAppForm with scrollbars and attachmentList

Aldo,

I don't think so. You should probably use the newer "layout" form capability (hiCreateLayoutForm, with hiCreateGridLayout etc) as this is a much more powerful and simpler way of having a decent geometry manager rather than the older attachment based approach. Here's a simple example:

procedure(abCreateBigLayoutForm(numFields)
    let((fields field label gridLay)
        for(i 0 numFields
            field=hiCreateStringField(?name concat('myfield i))
            label=hiCreateLabel(?name concat('label i) ?labelText
                sprintf(nil "Field %d" i)
            )
            fields=tconc(fields list(label 'row i 'col 0))
            fields=tconc(fields list(field 'row i 'col 1))
        )
        fields=tconc(fields list('col_stretch 0 0))
        fields=tconc(fields list('col_stretch 1 1))
        fields=car(fields)
        gridLay=hiCreateGridLayout(
            'gridLay
            ?items fields
        )
        hiCreateLayoutForm(
            'abBigLayoutForm
            "Big layout form"
            ;------------------------------------------------------------
            ; Add a stretchable region below the grid so that 
            ; the fields don't spread out vertically
            ;------------------------------------------------------------
            hiCreateVerticalBoxLayout(
                'vbox
                ?items list(
                    gridLay
                    list('stretch_item 1)
                )
            )
            ?minSize 600:200
        )
    )
)

Simply then call:

abCreateBigLayoutForm(10)
hiDisplayForm(abBigLayoutForm)

Andrew.

Thank you Andrew.

I have followed your suggestion, using disclosure triangles to replace the frames that cannot be used in layout forms. Is it possible to change font aspect to red & bold? Are there other alternatives to frames defined for app forms?

Many thanks

Best regards,

Aldo

Thank you Andrew.

I have followed your suggestion, using disclosure triangles to replace the frames that cannot be used in layout forms. Is it possible to change font aspect to red & bold? Are there other alternatives to frames defined for app forms?

Many thanks

Best regards,

Aldo

Hi Aldo,

Frames are still available, but created a different way. You use the ?frame argument to the functions that create a layout (i.e the functions that match this pattern: ^hiCreate.*Layout$). Since you can nest layouts within other layouts, you can effectively create your own widgets this way or implement frames as before. So this code:

procedure(abCreateFrameLayoutFields(startNum endNum)
    let((fields field label)
        for(i startNum endNum
            field=hiCreateStringField(?name concat('myfield i))
            label=hiCreateLabel(?name concat('label i) ?labelText
                sprintf(nil "Field %d" i)
            )
            fields=tconc(fields list(label 'row i 'col 0))
            fields=tconc(fields list(field 'row i 'col 1))
        )
        fields=tconc(fields list('col_stretch 0 0))
        fields=tconc(fields list('col_stretch 1 1))
        fields=car(fields)
    )
)

procedure(abCreateFrameLayoutForm()
    let((fields frameLay1 frameLay2)
        fields=abCreateFrameLayoutFields(0 3)
        frameLay1=hiCreateGridLayout(
            'frameLay1
            ?items fields
            ?frame "With Title"
        )
        fields=abCreateFrameLayoutFields(4 6)
        frameLay2=hiCreateGridLayout(
            'frameLay2
            ?items fields
            ?frame t ; no title
        )
        hiCreateLayoutForm(
            'abFrameLayoutForm
            "layout form with frames"
            ;------------------------------------------------------------
            ; Add a stretchable region below the grid so that 
            ; the fields don't spread out vertically
            ;------------------------------------------------------------
            hiCreateVerticalBoxLayout(
                'vbox
                ?items list(
                    frameLay1
                    frameLay2
                    list('stretch_item 1)
                )
            )
            ?minSize 600:200
        )
    )
)

hiDisplayForm(abCreateFrameLayoutForm())

produces this:

Regards,

Andrew.