clear list box value

Hi, the following sample should give you an example of how you could handle your problem (it only works in SKILL++ though)
The changeCB argument of hiCreateListBoxField is the right solution for this purpose but you have to be careful not looping it infinitely

Cheers

Aurélien

(inScheme
(let (form)

  (defun do_nothing (@rest _args)
    "Always return nil, whatever the inputs"
    nil)

  (defun create_form nil
    "Create the form"
    (hiCreateLayoutForm 'custom_form "Custom Form"
      (hiCreateFormLayout 'main_layout ?items (list
          (hiCreateListBoxField ?name 'list_box_field
            ?choices '("Design1" "Design2" "Design3" "Layout1" "Layout2" "Layout3")
            ?multipleSelect t
            ?changeCB
            (lambda (field form)
              ;; Here we are making sure to deactivate this change callback
              ;; before updating field value, this avoids generating an
              ;; infinite loop and crashing Virtuoso
              (let ((prev_cb field->changeCB))
                (setf field->changeCB do_nothing)
                (unwindProtect
                 ;; The following S-expression is run  in a safe environment
                 ;; Even if its body raises errors, `unwindProtect' will make
                 ;; sure to restore the updated changeCB to its previous value
                 (let ((choices (field->value)))
                   ;; Check and update input value
                   (cond
                     ;; No choice, do nothing
                     ((not choices)
                       nil)
                     ;; All choices are 'design', print success
                     ((forall choice choices (pcreMatchp "Design" choice))
                       (info "Success!\n"))
                     ;; All choices are 'layout', also print success
                     ((forall choice choices (pcreMatchp "Layout" choice))
                       (info "Success!\n"))
                     ;; If we reach this case, it means both 'design' and 'layout'
                     ;; choices are selected
                     ;; Clear selected values
                     (t
                       (setf field->value nil)
                       (error "Both 'design' and 'layout' choices were selected")
                       )))
                 (setf field->changeCB prev_cb)
                 ));unwindProtect ;let
              ));list_box_field
          ));main_layout
      ));def

  (defglobalfun display_gui (@rest _args)
    "Main function, display the GUI"
    (unless form (setq form (create_form)))
    (hiDisplayForm form))

  );closure
)

Thank you Aurel :)
If possible can you guide in Skill     as Skill++ is very very new to me.

procedure( back(field form)
  let( (prev_cb)
    prev_cb=field->changeCB
    field->changeCB=(lambda (@rest _args) nil)
    (if forall( choice field->value (pcreMatchp "design" choice)) || forall( choice field->value (pcreMatchp "layout" choice))
       ;; choices are all design or all layout
       info("Success!\n")
       ;; choices are a mix of design and layout
       progn(
         hiDisplayAppDBox( ?name 'errorbox2 ?dboxBanner "Error" ?dboxText "wrong selected" ?dialogType hicErrorDialog ?buttonLayout 'Close ?buttons 'Cancel)
         form->check->value = nil ;;;;;;;;;;;; to clear the selected value from listbox ;;;;;;;;;;;
         ))
    field->changeCB=prev_cb
    ))


check=hiCreateListBoxField(
?name 'check
?multipleSelect t
?changeCB 'back
?choices list("design1" "design2" "design3" "layout1" "layout2" "layout3")
)

procedure( back(field form)
  let( (prev_cb)
    prev_cb=field->changeCB
    field->changeCB=(lambda (@rest _args) nil)
    (if forall( choice field->value (pcreMatchp "design" choice)) || forall( choice field->value (pcreMatchp "layout" choice))
       ;; choices are all design or all layout
       info("Success!\n")
       ;; choices are a mix of design and layout
       progn(
         hiDisplayAppDBox( ?name 'errorbox2 ?dboxBanner "Error" ?dboxText "wrong selected" ?dialogType hicErrorDialog ?buttonLayout 'Close ?buttons 'Cancel)
         form->check->value = nil ;;;;;;;;;;;; to clear the selected value from listbox ;;;;;;;;;;;
         ))
    field->changeCB=prev_cb
    ))


check=hiCreateListBoxField(
?name 'check
?multipleSelect t
?changeCB 'back
?choices list("design1" "design2" "design3" "layout1" "layout2" "layout3")
)

Thank you Aurel   !!!!!!!!!!! :)