"Fixed"+"scalable" stretch form

Martin,

This example of using nested layouts should show you how to do this - it's a silly made up example that shows the contents of analogLib on the right, and the left fields show the last selected item in the report field. As you resize the form, the report field expands right and downwards, but the left fields stay where they are.

procedure(CCFcreateFormWithReportField()
  let((report lib lcvList libField cellField viewField libLabel cellLabel 
      viewLabel leftGrid)
    ; create some contents for a report field
    lib=ddGetObj("analogLib")
    foreach(cell lib~>cells
      foreach(view cell~>views
        lcvList=cons(list(lib~>name cell~>name view~>name) lcvList)
      )
    )
    lcvList=sort(lcvList 
      lambda((a b)
        cond(
          (alphalessp(cadr(a) cadr(b)) t)
          (equal(cadr(a) cadr(b)) && alphalessp(caddr(a) caddr(b)) t)
          (t nil)
        )
      ))
    report=hiCreateReportField(
      ?name 'report
      ?headers list(
        list("Library" 100 'left 'string t)
        list("Cell" 100 'left 'string t)
        list("View" 100 'left 'string t)
      )
      ?choices lcvList
      ?selectMode 'single
      ?callback lambda((field _scope selectedItems)
        let((choice (form hiGetCurrentForm()))
          choice=nth(car(selectedItems) field->choices)
          form->lib->value=car(choice)
          form->cell->value=cadr(choice)
          form->view->value=caddr(choice)
        )
      )
    )
    libField=hiCreateStringField(
      ?name 'lib
    )
    cellField=hiCreateStringField(
      ?name 'cell
    )
    viewField=hiCreateStringField(
      ?name 'view
    )
    libLabel=hiCreateLabel(
      ?name 'libLabel
      ?labelText "Library"
      ?justification 'right
    )
    cellLabel=hiCreateLabel(
      ?name 'cellLabel
      ?labelText "Cell"
      ?justification 'right
    )
    viewLabel=hiCreateLabel(
      ?name 'viewLabel
      ?labelText "View"
      ?justification 'right
    )
    ;--------------------------------------------------------------------
    ; Create the left panel as a grid layout
    ;--------------------------------------------------------------------
    leftGrid=hiCreateGridLayout(
      'leftGrid
      ?items list(
        list(libLabel 'row 0 'col 0)
        list(libField 'row 0 'col 1)
        list(cellLabel 'row 1 'col 0)
        list(cellField 'row 1 'col 1)
        list(viewLabel 'row 2 'col 0)
        list(viewField 'row 2 'col 1)
        list('col_min_width 0 80)
        list('col_min_width 1 100)
        list('col_stretch 0 0)
        list('col_stretch 1 0)
      )
    )
    hiCreateLayoutForm(
      'CCFformWithReportFieldForm
      "Form with Report"
      ;------------------------------------------------------------------
      ; use a horizontal box layout for the left grid (non-stretchy)
      ; and the report (stretchy)
      ;------------------------------------------------------------------
      hiCreateHorizontalBoxLayout(
        'all
        ?items list(
          list(
            ;------------------------------------------------------------
            ; The vertical box layout is to add a stretch item below
            ; the leftGrid which will expand to fill the vertical space;
            ; This keeps the left fields in the same place vertically
            ;------------------------------------------------------------
            hiCreateVerticalBoxLayout(
              'vbox
              ?items list(
                leftGrid
                list('stretch_item 1)
              )
            )
            'stretch 0)
          list(report 'stretch 1)
        )
      )
    )
  )
)

procedure(CCFformWithReportField()
  unless(boundp('CCFformWithReportFieldForm)
    CCFcreateFormWithReportField()
  )
  hiDisplayForm(inSkill(CCFformWithReportFieldForm))
)

Regards,

Andrew

Thanks Andrew! It works.

Thanks Andrew! It works.