How to print all possible combinations from an input list.

I got this to work for a list that has 9 cdf parameters defined. I named the input list "tests"

    foreach(test tests
      cellName = car(test)
      printf("Testing %s\n" cellName)
      test = cdr(test)
      testValues = list()
      foreach(param test
        param = parseString(param " ")
        param = list(stringToSymbol(car(param)) parseString(cadr(param) ":"))
        testValues = append1(testValues param)
      ) ; foreach
      ;println(testValues)
      foreach(i0 cadr(nth(0 testValues))
      foreach(i1 cadr(nth(1 testValues))
      foreach(i2 cadr(nth(2 testValues))
      foreach(i3 cadr(nth(3 testValues))
      foreach(i4 cadr(nth(4 testValues))
      foreach(i5 cadr(nth(5 testValues))
      foreach(i6 cadr(nth(6 testValues))
      foreach(i7 cadr(nth(7 testValues))
      foreach(i8 cadr(nth(8 testValues))
        printf("dbCreateParamInstByMasterName(cvId \"myLib" \"%s\" \"layout\" nil 0:0 \"R0\" 1\nlist(" cellName)
        printf("%L %L\n" car(nth(0 testValues)) i0)
        printf("%L %L\n" car(nth(1 testValues)) i1)
        printf("%L %L\n" car(nth(2 testValues)) i2)
        printf("%L %L\n" car(nth(3 testValues)) i3)
        printf("%L %L\n" car(nth(4 testValues)) i4)
        printf("%L %L\n" car(nth(5 testValues)) i5)
        printf("%L %L\n" car(nth(6 testValues)) i6)
        printf("%L %L\n" car(nth(7 testValues)) i7)
        printf("%L %L)\n)\n" car(nth(8 testValues)) i8)
      )))))))))

It's ugly and it is required to know the number of parameters in advance.

Here's a solution that uses recursion:

procedure( permuteParams(paramList @optional retVal)
  if(length(paramList) == 0 then
     foreach(i retVal
       printf("%s %L\n" car(i) cadr(i))
     ); foreach
     printf("\n")
  else
    let((entry pname plist)
      entry = car(paramList)
      paramList = cdr(paramList)
      pname = car(entry)
      plist = cadr(entry)
      foreach(value plist
        retVal = append1(retVal list(pname value)) ;; push
        permuteParams(paramList retVal)              ;; recurse
        retVal = reverse(cdr(reverse(retVal)))          ;; pop
      ); foreach
    ); let
  ); if
); procedure

I was thinking about this overnight, and indeed a recursive solution is a good way of implementing this. Mine is more efficient (uses less memory and is faster. because it's not using append and reverse throughout), and also returns a list of all the results for convenience:

procedure(CCFgenerateParamPermutations(assocList @optional cumulative results)
  if(assocList then
    let(((paramName caar(assocList)))
      foreach(value cadar(assocList)
        results=CCFgenerateParamPermutations(
          cdr(assocList)
          cons(list(paramName value) cumulative)
          results
        )
      )
    )
  else
    results=cons(cumulative results)
  )
  results
)

Then you can do:

allPerms=CCFgenerateParamPermutations(data)

where data is your input assoc list.

Andrew

Hi Andrew,

This works very well

Thanks,

Hi Andrew,

This works very well

Thanks,