Skill code to Get all the lib and views used in cell from top to bottom hierarchy

Hi Manju,

The following snippet might be a good start for you

(inScheme
(let ()

  (defun get_view_type (lib cell view "ttt")
    "Return LIB/CELL/VIEW view type, return nil if LIB/CELL/VIEW does not exist"
    ;;  From Cadence Support: "How can I get view type of cellView using SKILL?"
    ;; support.cadence.com/.../ArticleAttachmentPortal
    (and (eq 'ddViewType (type (ddGetObj lib cell view)))
         (ddMapGetFileViewType (ddGetObj lib cell view "*"))
         ));and ;def

  (defun get_sch_view (lib cell "tt")
    "Return first valid schematic view name out of LIB/CELL"
    (when (eq 'ddCellType (type (ddGetObj lib cell)))
      (car (exists view (parseString (envGetVal "schematic" "viewNameList" 'string))
             (equal "schematic" (get_view_type lib cell view))
             ))
      ));when ;def

  (defun apply_to_hierarchy (fun cv)
    "Apply FUN recursively to all cellviews from CV hierarchy"
    (funcall fun cv)
    (foreach sub_cv cv->instanceMasters
      (apply_to_hierarchy fun sub_cv)
      ;; When view is a symbol one, apply also fun to associated schematic one
      (when (equal "schematicSymbol" sub_cv->cellViewType)
        (letseq ((sch_view (get_sch_view sub_cv->libName sub_cv->cellName))
                 (sch_cv   (and sch_view (dbOpenCellViewByType sub_cv->libName sub_cv->cellName sch_view)))
                 )
          (when sch_cv (unwindProtect (apply_to_hierarchy fun sch_cv) (dbClose sch_cv)))
          ));letseq ;when
      ));foreach ;def

  (defglobalfun cst_flatten_hierarchy (cv "d")
    "Return flat hierarchy from CV"
    ;; Create and fill table containing all lib/cell/view tuples
    (let ((table (makeTable 'lcv nil)))
      (apply_to_hierarchy
        (lambda (cv) (setf table[(list cv->libName cv->cellName cv->viewName)] t))
        cv)
      ;; Return all lib/cell/view tuples
      table[?]))

  ));Scheme closure

It should work on both schematic and layout views (not on config views though)

Cheers

Aurélien

Manjunath,

Another method would be to get the hierarchy tree from layout and process the output with shell (sort and uniq). This approach also works in terminal with 'fasttree' command

-Ramakrishnan

Hi RamaKrishanan, 

Thanks for the reply, let me try that. 

regards

Manjunath

Hi RamaKrishanan, 

Thanks for the reply, let me try that. 

regards

Manjunath