How to select all floating wires in a schematic (both connected to terminals or not connected to a terminal)

Here's the code that get the floating wires using schCheck

tramt don't hesitate if you have questions about it as this can appear complex SKILL++ if you are not familiar with Scheme

;; `inScheme' used as this is SKILL++ file
;; if current file extension is .ils, this can be skipped
(inScheme
(let ()

  (defun get_floating_wires (cv)
    "Run `schCheck' to extract CV connectivity then return
 the list of wires having an associated 'floating' marker"
    (schCheck cv)
    (foreach mapcan marker cv->markers
      (and (pcreMatchp "floating" marker->msg (pcreGenCompileOptBits ?caseLess t))
           (forall obj marker->objects (equal "line" obj->objType))
           marker->objects
           )))

  (defun get_connected_wires (wire)
    "Return the list of wires connected to WIRE (including itself)"
    (let ((done_wires  (makeTable t nil))
          (to_do_wires (list wire))
          )
      ;; to_do_wires is a list of all wires whose neighbours have not been fetched yet
      ;; wires in this list are processed one by one until the list is empty
      (while to_do_wires
        ;; Fetch next wire to process, mark it as done immediately to avoid
        ;; reprocessing it
        (setq wire (pop to_do_wires))
        (setf done_wires[wire] t)
        ;; Add connected wires that have not been processed yet to to_do_wires list
        (foreach obj (dbProduceOverlap wire->cellView wire->bBox 0)
          (when (and (equal "line" obj->objType)
                     (equal obj->net wire->net)
                     (not done_wires[obj])
                     )
            (push obj to_do_wires)
            )))
      ;; Return the list of done wires
      done_wires[?]
      ))

  (defglobalfun ab_select_floating_wires ( @key  (cv (geGetEditCellView))
                                           @rest _
                                           )
    "Select floating wires in CV (this implies running `schCheck' which extracts connectivity)"
    ;; Make sure input cellview is a schematic one
    (assert (equal "schematic" cv->cellViewType) "Not a schematic view: %s/%s/%s"
      cv->libName cv->cellName cv->viewName)
    ;; Fetch and select floating wires
    (mapc 'geSelectFig (mapcan get_connected_wires (get_floating_wires cv)))
    )

  );closure
  );inScheme

Here's the code that get the floating wires using schCheck

tramt don't hesitate if you have questions about it as this can appear complex SKILL++ if you are not familiar with Scheme

;; `inScheme' used as this is SKILL++ file
;; if current file extension is .ils, this can be skipped
(inScheme
(let ()

  (defun get_floating_wires (cv)
    "Run `schCheck' to extract CV connectivity then return
 the list of wires having an associated 'floating' marker"
    (schCheck cv)
    (foreach mapcan marker cv->markers
      (and (pcreMatchp "floating" marker->msg (pcreGenCompileOptBits ?caseLess t))
           (forall obj marker->objects (equal "line" obj->objType))
           marker->objects
           )))

  (defun get_connected_wires (wire)
    "Return the list of wires connected to WIRE (including itself)"
    (let ((done_wires  (makeTable t nil))
          (to_do_wires (list wire))
          )
      ;; to_do_wires is a list of all wires whose neighbours have not been fetched yet
      ;; wires in this list are processed one by one until the list is empty
      (while to_do_wires
        ;; Fetch next wire to process, mark it as done immediately to avoid
        ;; reprocessing it
        (setq wire (pop to_do_wires))
        (setf done_wires[wire] t)
        ;; Add connected wires that have not been processed yet to to_do_wires list
        (foreach obj (dbProduceOverlap wire->cellView wire->bBox 0)
          (when (and (equal "line" obj->objType)
                     (equal obj->net wire->net)
                     (not done_wires[obj])
                     )
            (push obj to_do_wires)
            )))
      ;; Return the list of done wires
      done_wires[?]
      ))

  (defglobalfun ab_select_floating_wires ( @key  (cv (geGetEditCellView))
                                           @rest _
                                           )
    "Select floating wires in CV (this implies running `schCheck' which extracts connectivity)"
    ;; Make sure input cellview is a schematic one
    (assert (equal "schematic" cv->cellViewType) "Not a schematic view: %s/%s/%s"
      cv->libName cv->cellName cv->viewName)
    ;; Fetch and select floating wires
    (mapc 'geSelectFig (mapcan get_connected_wires (get_floating_wires cv)))
    )

  );closure
  );inScheme