how to display the coordinates at mouse, or display *+coord(x,y)

This is not a persistent marker, but you can add to the current window (it doesn't save in the database) and then create screenshots, for example. It wasn't clear what you wanted:

/* CCFaddCoordHilight.ils

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date        
Modified   
By         

Functions for creating hilights on the layout to mark a given
coordinate. See the comments above each function to understand
how each function works.

***************************************************

SCCS Info: @(#) CCFaddCoordHilight.ils 03/14/25.15:14:37 1.1

*/

;------------------------------------------------------------------------
; Add a cross and a label at the given point. Keyword arguments can
; control the size and appearance of the hilight. Returns the drawn
; hilights as a group - this can then be passed to CCFdeleteCoordHilight
; to delete the object.
;------------------------------------------------------------------------
procedure(CCFaddCoordHilight(point @key (winId hiGetCurrentWindow()) 
        (lpp "y0") (crossSize 0.2) (fontSize 0.2) (font "stick") 
        (justify "lowerLeft"))
    let((hs (cv geGetEditCellView(winId)) (diagOff 0.7*crossSize))
        hs=winId~>coordHilightSet || geCreateHilightSet(cv lpp)
        winId~>coordHilightSet=hs
        hs~>enable=t
        destructuringBind((x y) point
            geCreateHilightGroup(
                hs
                list(
                    geAddHilightLine(hs list(x:y+crossSize x:y-crossSize))
                    geAddHilightLine(hs list(x-crossSize:y x+crossSize:y))
                    geAddHilightLine(hs list(x-diagOff:y-diagOff x+diagOff:y+diagOff))
                    geAddHilightLine(hs list(x-diagOff:y+diagOff x+diagOff:y-diagOff))
                    geAddHilightLabel(hs 
                        x+diagOff:y
                        lsprintf("(%g,%g)" x y)
                        justify
                        "R0"
                        font
                        fontSize
                        t
                    )
                )
            )
        )
    )
)

;------------------------------------------------------------------------
; Either delete an individual hilight (as returned by CCFaddCoordHilight) or
; if passed t, will delete all of them
;------------------------------------------------------------------------
procedure(CCFdeleteCoordHilight(coordHilight @key (winId hiGetCurrentWindow()))
    cond(
        (coordHilight==t
            foreach(group winId~>coordHilightSet~>groups
                geDeleteHilightGroup(group t)
            )
            t
        )
        (geIsValidHilightGroup(coordHilight)
            geDeleteHilightGroup(coordHilight t)
        )
    )
)

;------------------------------------------------------------------------
; Callback function for CCFhiAddCoordHilight. Add keyword arguments
; if you want to alter the appearance (could have created an options form
; but didn't want to spend that much time on it!)
;------------------------------------------------------------------------
procedure(CCFhiAddCoordHilightCB(winId done pts)
    when(done
        CCFaddCoordHilight(car(pts) ?winId winId)
    )
)

;------------------------------------------------------------------------
; Example of prompting the user to enter a coordinate hilight
;------------------------------------------------------------------------
procedure(CCFhiAddCoordHilight()
    enterPoint(
        ?prompts list("Enter location of coordinate hilight")
        ?doneProc "CCFhiAddCoordHilightCB"
    )
)

Here's what it looks like:

If you want it persistently saved in the cellView, you could create a figGroup with dbCreateFigGroup, and then use dbCreateLine and dbCreateLabel inside, instead of using the ge.*Hilight functions that I've used here. I'll leave that as an exercise for you...

Andrew

Thank you very much for your answer
You're right, I just want this effect
My idea is to make a temporary mark (including coordinates), like a ruler, so that when I don't need it, I can shift+k and delete it.
I need this effect to have a purpose, for example, if there is a DRC error in this area, then I can send it to my partner through this method for him to modify.