Script to select all the shapes connected to a pin

Assuming that the layout has connectivity (e.g. was done in Virtuoso Layout Suite XL), then maybe this is what you want? The idea is that you select the pins, and then call abSelectWholeNet() will then select everything on the nets for those pins. 

/* abSelectWholeNet.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       May 16, 2001 
Modified   Feb 26, 2009 
By         A.D.Beckett

Updated to work with layout in CDB, where vias are instances with instTerms
on the net; in OA vias are directly attached to the net.

***************************************************

SCCS Info: @(#) abSelectWholeNet.il 02/26/09.14:08:25 1.2

*/

/***************************************************************
*                                                              *
* (abSelectWholeNet @optional (cellView (geGetEditCellView)))  *
*                                                              *
*   Select the whole of each net that is partially selected.   *
*                                                              *
***************************************************************/

(procedure (abSelectWholeNet @optional (cellView (geGetEditCellView)))
  (let (nets theNet)
       (foreach shape (geGetSelSet cellView)
                (setq theNet (dbGetq shape net))
                (unless (member theNet nets) (setq nets (cons theNet nets)))
                )
       (foreach net nets
                ;--------------------------------------------------------
                ; Find all the figures on the net
                ;--------------------------------------------------------
                (foreach fig (dbGetq net figs)
                         (geSelectFig fig)
                         ) ; foreach fig
                ;--------------------------------------------------------
                ; Find all the vias on the net - only do this in CDB
                ; when leIsContact function exists
                ;--------------------------------------------------------
                (when (isCallable 'leIsContact)
                  (foreach inst (dbGetq (dbGetq net instTerms) inst)
                           (when (leIsContact inst)
                             (geSelectFig inst))
                           ) ; foreach inst
                  ) ; when 
                ;--------------------------------------------------------
                ; Find all the pin figures on the net
                ;--------------------------------------------------------
                (foreach pin (dbGetq net pins)
                         (foreach fig 
                                  (or 
                                    (dbGetq pin figs) 
                                    (list (dbGetq pin fig))
                                    )
                                  (geSelectFig fig)
                                  ) ; foreach fig
                         ) ; foreach pin
                ) ; foreach net
       t
       ) ; let
  ) ; procedure

Hi Becket, Thanks for the quick reply.

Looks like the script works only if the layout is annotation clean. It doesn't work if the layout doesn't have the connectivity.

Thanks,

Ganesh

Hi Becket, Thanks for the quick reply.

Looks like the script works only if the layout is annotation clean. It doesn't work if the layout doesn't have the connectivity.

Thanks,

Ganesh

Ganesh,

You could run lceExtract(geGetEditCellView()) to run the connectivity extractor, and then use the code?

Andrew