How to get desired field size in Layout forms

Hi,

Inside hiCreateVerticalBoxLayout and hiCreateHorizontalBoxLayout, you can set the "stretchiness" ratio of each field by doing this

instead of providing ?items (list field)

You can do ?items (list (list field 'stretch 1))  

You can also add 'stretch_item and 'spacer_item

You can also set the minimum field dimensions with hiSetFieldMinSize.

Once used to this, you will normally never use an AppForm again. (Or only for legacy purposes...)

I did not have the time yet (and I'm trying to answer before Andrew) but I can provide you with examples if you need.

Hope this helps,

Aurel

Hi Aurel,

Thanks. Should we mention the min size using pixel counts for hiSetFieldMinSize? That is how I read in the documents which is kind of going back to AppForms.

I tried 'stretch 0 so that the items will not stretch but it did.

Could you also clarify between  'stretch <int> vs 'stretch_item <int> ?

Thanks a lot

Ram

Hi Aurel,

Thanks. Should we mention the min size using pixel counts for hiSetFieldMinSize? That is how I read in the documents which is kind of going back to AppForms.

I tried 'stretch 0 so that the items will not stretch but it did.

Could you also clarify between  'stretch <int> vs 'stretch_item <int> ?

Thanks a lot

Ram

Ram,

Seeing your code would help here, otherwise we're having to guess. The documentation explains that 'stretch controls the stretchiness of a field, whereas 'stretch_item allows you to add a stretchable spacer between the fields (so this can absorb the extra space rather than fields getting wider). 

An easy way to control the minimum width is to use 'col_min_width in a grid layout - this example uses this (column 0 just has labels in my case, but I am able to specify the minimum width of that column nevertheless. It's in pixels.

procedure(ExGrid()
  let((grid)
    grid=hiCreateGridLayout(
      'grid
      ?items
        list(
          list(
            hiCreateLabel(
              ?name 'enableLabel
              ?labelText "Enable"
            )
            'row 0 'col 0
          )
          list(
            hiCreateBooleanButton(
              ?name 'enable
              ?buttonText " "
            )
            'row 0 'col 1
          )
          list(
            hiCreateLabel(
              ?name 'libLabel
              ?labelText "Lib"
            )
            'row 1 'col 0
          )
          list(
            hiCreateStringField(
              ?name 'lib
            )
            'row 1 'col 1
          )
          list(
            hiCreateLabel(
              ?name 'cellLabel
              ?labelText "Cell"
            )
            'row 2 'col 0
          )
          list(
            hiCreateStringField(
              ?name 'cell
            )
            'row 2 'col 1
          )
          list(
            hiCreateLabel(
              ?name 'viewLabel
              ?labelText "View"
            )
            'row 3 'col 0
          )
          list(
            hiCreateStringField(
              ?name 'view
            )
            'row 3 'col 1
          )
          list(
            hiCreateLabel(
              ?name 'explanation
              ?labelText "Fields can also span across multiple columns or rows"
            )
            'row 4 'col 0 'col_span 2
          )
          ; only the entry fields are stretchable
          ; the labels do not stretch
          list('col_stretch 0 0)
          list('col_stretch 1 1)
; if you comment this out, you'll get the default width needed to fit the labels
          list('col_min_width 0 100)
        )
      ?frame "Grid Layout"
    )
    hiCreateLayoutForm(
      'ExGridLayout
      "Grid"
      ; surround the grid with a vertical box layout
      ; to provide a stretch_item below to prevent fields
      ; spreading vertically when the form is stretched
      hiCreateVerticalBoxLayout(
        'vbox
        ?items
          list(
            grid
            list('stretch_item 1)
          )
      )
;      ?dialogStyle 'modal
    )
    hiDisplayForm(ExGridLayout)
  )
)

Andrew

RK56 said:

Thanks. Should we mention the min size using pixel counts for hiSetFieldMinSize? That is how I read in the documents which is kind of going back to AppForms.

Yes, you should provide the same values to hiSetFieldMinSize as you would do for an AppForm.
But I cannot let you say that it's "kind of going back to AppForms" !

You can specify the minimum width in case you need it, to correct the display of a field, align some stuff, etc.
But you don't lose the stretchiness and all the other dynamic parameters that layout forms calculate for you.

I made an example of what you can achieve using layout forms with stretch and spacer items.

The code is a bit dense, but if you load it, you will get a visual feedback and see how stretchiness works.

(defun placeholder_field ( text @key min_h_size min_v_size )
  "Create a custom placeholder field to highlight stretching and return it."
  (letseq ( ( name  (gensym 'placeholder_layout)                   )
            ( field (hiCreateHorizontalBoxLayout name ?frame text) )
            )
    ;; Set minimum dimensions when provided
    (when (or min_h_size min_v_size)
      (hiSetFieldMinSize field name ?widgetWidth (or min_h_size 0) ?widgetHeight (or min_v_size 0))
      )
    field))

(hiDisplayForm
  (hiCreateLayoutForm (gensym 'custom_form) "Custom Form"
    (hiCreateVerticalBoxLayout 'main_layout ?items (list

        (list
          (hiCreateHorizontalBoxLayout 'h0 ?frame "Vertical Stretch 5" ?items (list
              (placeholder_field "No Stretch")
              (list (placeholder_field "Stretch 1") 'stretch 1)
              (list (placeholder_field "Stretch 0") 'stretch 0)
              (list (placeholder_field "Stretch 4") 'stretch 4)
              ))
          'stretch 5)
        '(spacer_item 50)

        (list
          (hiCreateHorizontalBoxLayout 'h1 ?frame "Vertical Stretch 2" ?items (list
              (placeholder_field "No Stretch")
              (list (placeholder_field "Stretch 1") 'stretch 1)
              '(stretch_item 2)
              (list (placeholder_field "Stretch 0") 'stretch 0)
              '(spacer_item 30)
              (list (placeholder_field "Stretch 4") 'stretch 4)
              ))
          'stretch 2)

        '(stretch_item 1)

        (list
          (hiCreateHorizontalBoxLayout 'h2 ?frame "Vertical Stretch 3" ?items (list
              (placeholder_field "No Stretch")
              (list (placeholder_field "Stretch 1 - MinWidth 50" ?min_h_size 50) 'stretch 1)
              '(stretch_item 1)
              (list (placeholder_field "Stretch 0 - MinWidth 100" ?min_h_size 100) 'stretch 0)
              '(spacer_item 30)
              (list (placeholder_field "Stretch 1") 'stretch 1)
              ))
          'stretch 3)
        ))
    ?buttonLayout 'Empty
    ))

Thanks Aurel and Andrew. Your code and the comments in those are helpful. I'm getting a hold of these now.