Schematic instance showing the config view selected.

Selcuk,

In the configured schematic, do Launch->Plugins->Hierarchy Editor, and then pick Hierarchy Editor->Show Views Found

Andrew.

Thanks Andrew,

What I was looking for is more like annotating the view (the one selected HED for this instance) on the instance in virtuoso.

Similar to showing the instance name I want to see the view selected. Is it possible?

Well maybe this article (one of mine) might help SKILL : Adding a label to a symbol to indicate which view is used from a config - although I suspect you're wanting a visual annotation which doesn't need adding a label onto the symbol.

You could use the code in that article together with this code here; you simply select the instances you want to annotate (or cross-select from the hierarchy editor) and call CCFannotateView() (maybe from a bindkey). You can also use CCFclearAnnotateView() to clear all the annotations.

procedure(CCFannotateView(@key (instances geGetSelSet()) 
        (window hiGetCurrentWindow()) (lpp list("y0" "drawing"))
        (height 0.0625)
        )
    let((hs bBox)
        hs=window~>CCFannotateViewHS || 
            geCreateHilightSet(geGetEditCellView(window) lpp)
        foreach(inst instances
            when(inst~>objType=="inst"
                bBox=dbTransformBBox(
                    dbComputeBBoxNoNLP(inst~>master) 
                    inst~>transform
                )
                when(bBox
                    geAddHilightLabel(hs centerBox(bBox) CCSwhichView(inst) 
                        "centerCenter" "R0" "stick" height t)
                )
            )
        )
        hs~>enable=t
        window~>CCFannotateViewHS=hs
        t
    )
)

procedure(CCFclearAnnotateView(@key (window hiGetCurrentWindow()))
    let((hs)
        hs=window~>CCFannotateViewHS
        when(hs
            geDeleteHilightSet(hs)
            window~>CCFannotateViewHS=nil
            t
        )
    )
)

Andrew

Thanks Andrew! This is exactly what I was looking for!