Procedure in the while loop

From the 'Cadence SKILL Language User Guide' documentation:

Use the prog function and the return function to exit early from a for loop. This example
finds the first odd integer less than or equal to 10.

prog( ( )
for( i 0 10
when( oddp( i )
return( i )
) ; when
) ; for
) ; prog

However, I don't know of any way of detecting a key press ( such as 'escape' ) since Allegro doesn't appear to support bindkeys

What are you planning  to do in the loop? 

If it is some user interaction with selection then use the axlEnterEvent() .

Otherwise look at the axlCancelOff, axlCancelOn, axlCancelTest  functions.

Hi B Bruekers,

I have a code to align the vias (vertical or horizonthal). I want to align the VIAS inside of the while loop. The VIAs are selected using

dbid_vias = axlGetSelSet(axlSingleSelectBox()). For example I select three VIAs to aligne them, then next four VIAs, then next ten Vias and so on.

This function should work until Escape (or another termination) is pressed, which means "No more VIAs to aligned".

I hope this explained a function.

Best regards

Juri

Then you need to use axlEnterEvent().  So something like this:

;start "myselection" from the command line of Allegro
axlCmdRegister( "myselection" 'SelectonLoop  ?cmdType "interactive")

procedure( SelectonLoop()
    let( (loop msg event StartXY)
         axlSetFindFilter( ?enabled '("noall" "vias") ?onButtons "vias")
        msg= "Select vias"
        loop = t
        while( loop
            event = axlEnterEvent(list('PICK 'PICK_EXTEND 'PICK_TOGGLE 'STARTDRAG 'STARTDRAG_EXTEND 'STARTDRAG_TOGGLE 'STOPDRAG 'STOPDRAG_EXTEND 'STOPDRAG_TOGGLE ) msg nil)
            caseq(event->type
                (PICK                  when(axlAddSelectPoint(event->xy), doSomethingWithSelection()))
                (PICK_EXTEND     when(axlAddSelectPoint(event->xy), doSomethingWithSelection()))
                (PICK_TOGGLE     when(axlSubSelectPoint(event->xy), doSomethingWithSelection()))
                (STARTDRAG
                    axlAddSimpleRbandDynamics(event->xySnap "box" ?var_point 0-car(event->xySnap):0-cadr(event->xySnap))
                    StartXY= event->xy
                )
                ((STARTDRAG_EXTEND STARTDRAG_TOGGLE)
                    axlAddSimpleRbandDynamics(event->xySnap "box" ?var_point 0-car(event->xySnap):0-cadr(event->xySnap))
                    StartXY= event->xy
                )
                (STOPDRAG                  
                    axlClearDynamics()
                    when(axlAddSelectBox(list(StartXY event->xy))
                        doSomethingWithSelection()
                    )
                    StartXY = 0
                )
                (STOPDRAG_EXTEND     axlClearDynamics(), when(axlAddSelectBox(list(StartXY event->xy)), doSomethingWithSelection()),    StartXY=0 )
                (STOPDRAG_TOGGLE    axlClearDynamics(), when(axlSubSelectBox(list(StartXY event->xy)), doSomethingWithSelection()),    StartXY=0 )
                (DONE         
                    doSomethingWithSelection()
                    loop = nil
                )
                (CANCEL     
                    loop = nil
                )
            )
        )
    )
)

procedure( doSomethingWithSelection()
    let( (selectedItems)
        when(selectedItems = axlGetSelSet()
            pp(selectedItems)
        )
    )
)

OK, Thank you.
I used such function for PICK, but not for CANCEL or DONE. Are CANCEL and DONE like Escape or the popup for RMB with Cancel and Done functions should be define?

Best regards

Juri