How to create templates for vdd/vss nets in Virtuoso

The way we handle this on our designs is with a pcell. We have a pcell that we place down that contains our power rails and parts of unclosed guardrings. You can change the pcell width to be as wide as you need for the area where you are working. Below I have included a very quick hack of a pcell that contains a rectangle for vss and a rectangle for vdd, as well as a rectangle for the boundary of the cell. I put a stretch handle on the cell boundary that will allow you to stretch the width of the pcell.

Things to note:
I used both rodCreateRect and dbCreateRect. The dbCreateRect is much more efficient for designs with lots of pcells. The rodCreateRect allowed me to create the stretch handle for the width parameter.
I only added three parameters, one for the height of vss, one for the height of vdd and one for the width of the template. The offset locations for the rails were hard coded.
I used layers y0 and y1 since they are Cadence system layers and will exist in your design. You should use your actual metal layer for vss and vdd. If you are working in 6.1.x, you should use the Cadence dbCreatePRBoundary command. If you are in 5.1.x, you should use the lpp "prBoundary" "boundary".
I did not create a CDF, so the parameters will appear on the Edit Properites form as "w", "vssH" and "vddH". For cleaner control of your parameters and how they are displayed to your users, you'll want to create a CDF.

procedure(myCreateTemplatePcell(@optional (myLib "myLib") (dev "template"))
  pcDefinePCell(
  list(ddGetObj(myLib) dev "layout")
   ((w       "float" 10.0)
    (vddH    "float"  5.0)
    (vssH    "float"  5.0)
   )
    let((cv y)
        cv = pcCellView
        vddYOffset = 2.0
        dbCreateRect(cv list("y0" "drawing") list(0:vddYOffset w:vddH+vddYOffset))
        dbCreateLabel(cv list("text" "drawing") 0:vddYOffset "vdd" "lowerLeft" "R0" "roman" 2.0)

        vssYOffset = 2.0
        dbCreateRect(cv list("y0" "drawing") list(0:-vssYOffset w:-vssH-vssYOffset))
        dbCreateLabel(cv list("text" "drawing") 0:-vssYOffset "vss" "upperLeft" "R0" "roman" 2.0)

        boxId = rodCreateRect(
            ?name       "width"
            ?layer      list("y1" "drawing")
            ?origin     0:-vssH-vssYOffset
            ?width      w
            ?length     vddH + vssH + vddYOffset + vssYOffset
        )
        rodAssignHandleToParameter(
            ?parameter          'w
            ?rodObj             boxId
            ?handleName         "centerRight"
            ?displayName        "width"
            ?displayExpression  'w
            ?stretchDir         'x
            ?stretchType        "relative"
            ?moveOrigin         nil
            ?updateIncrement    1.0
        )

       
    )
  ); pcell
); proc

To create the pcell, first load this code in your CIW. Then run the following command, replacing "myLib" with the name of a Cadence library where you would like this pcell created:

myCreateTemplatePcell("myLib")

The default pcell name is "template", or you can pass in a different string as the second argument. Now you can place the pcell in your layout. You can either specify the width of the pcell when you place it, or by querying it, or by using the stretch handle.

If you are unfamiliar with pcells, please take a look at the Cadence documentation.

Hopefully this is a good start for what you are looking for. 

Derek

In IC61X you can also use the "Load Physical View" command to load data from a template cellView.

Regards,

Andrew.

 @Derek : Thanks for the script. Havent tried it yet due to other deadlines.

@Andrew: Unfortunately, have an older version. of IC. Any other way to load a template in older versions? Your way sounds very easy and intuitive. I have to still try the script from Derek though.

In IC5141, you can use (in Layout XL) Design->Save to Template from an existing view, and save info about the I/O pin locations or constraints.

This template file can be referenced at the bottom of the Design->Generate from Source form. Also, if you use Place->Pin Placement, you can choose to place pins as in a Template File. You can create (for example) the pins how you want (including using the Hrail/Vrail options) from this same Pin Placement form.

IC61X has a similar (but with further enhancements) pin placement UI.

Regards,

Andrew.