Stats

  • Locked Locked
  • Replies 1
  • Subscribers 125
  • Views 13827
  • Members are here 0
This discussion has been locked.
You can no longer post new replies to this discussion. If you have a question you can start a new discussion

RE: modifying default trace properties for a dft in ade

jorankin

I am wondering how to change the default trace properties for a dft. Currently spectral traces show up for dft's in ViVA. I would like to change this in my .cdsenv file so that the default is lines. I tried to do this using the following command, but it didn't work:

wavescan.trace type string "line"

 I found the above command in the cadence documentation for ic 6.1.5. I don't see a similar command for viva...I tried replacing wavescan with viva in the above statement, but it didn't work.

Thanks,

John

Parents
  • Andrew Beckett

    John,

    That won't help you because there's a hint on the waveform object produced by dft which overrides any default (and anyway I think that's an obsolete setting for the old Java graph - there's a CCR to get these removed from the docs).

    You could use the code below (comments at the top give a clue how to use it). Effectively wrapping your expression with abSetPlotStyle(... "joined") should do the trick, and there's a function to add this to the calculator to make it easier to use. 

    /* abSetPlotStyle.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Dec 10, 2009 
Modified   
By         

abSetPlotStyle(waveform "joined")

Sets a waveform to be plotted as joined. Can also be set to "bar" or
"scatterPlot" or "auto".

abRegSetPlotStyleSpecialFunction()

registers a function in the calculator to alter the plot style on a 
waveform.

***************************************************

SCCS Info: @(#) abSetPlotStyle.il 12/10/09.11:18:00 1.2

*/

/***************************************************************
*                                                              *
*               (abSetPlotStyle wave plotStyle)                *
*                                                              *
*   Set the plotStyle to one of "auto", "scatterPlot", "bar"   *
*     or "joined" (same as ocnHelp('plotStyle) choices) on     *
*                   the waveform passed in.                    *
*                                                              *
***************************************************************/

(defun abSetPlotStyle (wave plotStyle "gS")
  (setq plotStyle (concat plotStyle))
  (cond 
    ((drIsWaveform wave)
     (if (eq plotStyle 'auto)
       (remprop wave 'plotStyle)
       (putpropq wave plotStyle plotStyle)
       )
     )
    ((famIsFamily wave)
     (famMap 'abSetPlotStyle wave units)
     )
    )
  wave
  )

/***************************************************************
*                                                              *
*                  (abCreateSetPlotStyleForm)                  *
*                                                              *
*  Set up a form for the special function on the calculator,   *
* which gives choices for the plotStyle. It needs to be cyclic,*
*   because if it's a type in field, quotes don't get added    *
*                      around the units.                       *
*                                                              *
***************************************************************/

(defun abCreateSetPlotStyleForm ()
  (let (plotStyle)
    (setq plotStyle (ahiCreateCyclicField
                  ?name 'plotStyle
                  ?prompt "PlotStyle"
                  ?choices '("auto" "scatterPlot" "bar" "joined")
                  ?value "auto"
                  ))
    (calCreateSpecialFunctionsForm
      'abSetPlotStyleForm
      (list 
        (list plotStyle 0:0  180:20 140)
        )
      )
    ))

/*****************************************************************
*                                                                *
*               (abSetPlotStyleSpecialFunctionCB)                *
*                                                                *
*    Callback for the abSetPlotStyle special function, which     *
*     constructs the buffer input from the form and stack.       *
*                                                                *
*****************************************************************/

(defun abSetPlotStyleSpecialFunctionCB ()
  (calCreateSpecialFunction
   ?formSym 'abSetPlotStyleForm
   ?formInitProc 'abCreateSetPlotStyleForm
   ?formTitle "Set PlotStyle"
   ?formCallback 
   "(calSpecialFunctionInput 'abSetPlotStyle '(plotStyle))"
   ))


/***************************************************************
*                                                              *
*              (abRegSetPlotStyleSpecialFunction)              *
*                                                              *
*                Register the special function                 *
*                                                              *
***************************************************************/

(defun abRegSetPlotStyleSpecialFunction ()
  (calRegisterSpecialFunction
   (list "abSetPlotStyle..." 'abSetPlotStyleSpecialFunctionCB))
  t
  )

     

Reply
  • Andrew Beckett

    John,

    That won't help you because there's a hint on the waveform object produced by dft which overrides any default (and anyway I think that's an obsolete setting for the old Java graph - there's a CCR to get these removed from the docs).

    You could use the code below (comments at the top give a clue how to use it). Effectively wrapping your expression with abSetPlotStyle(... "joined") should do the trick, and there's a function to add this to the calculator to make it easier to use. 

    /* abSetPlotStyle.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Dec 10, 2009 
Modified   
By         

abSetPlotStyle(waveform "joined")

Sets a waveform to be plotted as joined. Can also be set to "bar" or
"scatterPlot" or "auto".

abRegSetPlotStyleSpecialFunction()

registers a function in the calculator to alter the plot style on a 
waveform.

***************************************************

SCCS Info: @(#) abSetPlotStyle.il 12/10/09.11:18:00 1.2

*/

/***************************************************************
*                                                              *
*               (abSetPlotStyle wave plotStyle)                *
*                                                              *
*   Set the plotStyle to one of "auto", "scatterPlot", "bar"   *
*     or "joined" (same as ocnHelp('plotStyle) choices) on     *
*                   the waveform passed in.                    *
*                                                              *
***************************************************************/

(defun abSetPlotStyle (wave plotStyle "gS")
  (setq plotStyle (concat plotStyle))
  (cond 
    ((drIsWaveform wave)
     (if (eq plotStyle 'auto)
       (remprop wave 'plotStyle)
       (putpropq wave plotStyle plotStyle)
       )
     )
    ((famIsFamily wave)
     (famMap 'abSetPlotStyle wave units)
     )
    )
  wave
  )

/***************************************************************
*                                                              *
*                  (abCreateSetPlotStyleForm)                  *
*                                                              *
*  Set up a form for the special function on the calculator,   *
* which gives choices for the plotStyle. It needs to be cyclic,*
*   because if it's a type in field, quotes don't get added    *
*                      around the units.                       *
*                                                              *
***************************************************************/

(defun abCreateSetPlotStyleForm ()
  (let (plotStyle)
    (setq plotStyle (ahiCreateCyclicField
                  ?name 'plotStyle
                  ?prompt "PlotStyle"
                  ?choices '("auto" "scatterPlot" "bar" "joined")
                  ?value "auto"
                  ))
    (calCreateSpecialFunctionsForm
      'abSetPlotStyleForm
      (list 
        (list plotStyle 0:0  180:20 140)
        )
      )
    ))

/*****************************************************************
*                                                                *
*               (abSetPlotStyleSpecialFunctionCB)                *
*                                                                *
*    Callback for the abSetPlotStyle special function, which     *
*     constructs the buffer input from the form and stack.       *
*                                                                *
*****************************************************************/

(defun abSetPlotStyleSpecialFunctionCB ()
  (calCreateSpecialFunction
   ?formSym 'abSetPlotStyleForm
   ?formInitProc 'abCreateSetPlotStyleForm
   ?formTitle "Set PlotStyle"
   ?formCallback 
   "(calSpecialFunctionInput 'abSetPlotStyle '(plotStyle))"
   ))


/***************************************************************
*                                                              *
*              (abRegSetPlotStyleSpecialFunction)              *
*                                                              *
*                Register the special function                 *
*                                                              *
***************************************************************/

(defun abRegSetPlotStyleSpecialFunction ()
  (calRegisterSpecialFunction
   (list "abSetPlotStyle..." 'abSetPlotStyleSpecialFunctionCB))
  t
  )

     

Children
No Data

Community Guidelines

The Cadence Design Communities support Cadence users and technologists interacting to exchange ideas, news, technical information, and best practices to solve problems and get the most from Cadence technology. The community is open to everyone, and to provide the most value, we require participants to follow our Community Guidelines that facilitate a quality exchange of ideas and information. By accessing, contributing, using or downloading any materials from the site, you agree to be bound by the full Community Guidelines.