automatically run a routine when a menu item is invoked from CIW or schematic window

There's no trigger as such, but you could easily modify the menu callbacks. For example:

procedure(CCFdoMyThing()
  printf("Doing my thing...\n")
)

pulldownMenu=ciwOptionsMenu
let((callback)
 foreach(menuItem hiGetMenuItems(pulldownMenu)
  callback=get(pulldownMenu menuItem)->_itemCallback
  when(stringp(callback)
    hiSetMenuItemCallback(pulldownMenu menuItem strcat("CCFdoMyThing() " callback))
  )
 )
)

Regards,

Andrew.

Thanks Andrew !

I was able to make it work with 'Options' menu but had issues :

1. It worked fine on item directly under main menu but does not trigger callback when used with for submenu item (for example does not work for Tools->AMS->Options but works fine for Tools->Library Manager)
2. Got error when I try using it on my 'Test' dropdown menu from CIW window (*Error* eval: unbound variable - ciwTestMenu).

Hi Vikash,

For the first item the code needs to traverse slider menus, so I altered the code to recursively all itself. See the example in the comments.

For the second, your menu is presumably not stored in a variable called ciwTestMenu - I'm guessing that you just guessed the name? Try typing hiGetBannerMenus(hiGetCIWindow()) to find out the menus in the CIW.

Regards,

Andrew.

/* CCFaddMenuTriggers.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Apr 19, 2013 
Modified   
By         

Example code to add triggers on menu items. For example:

procedure(CCFdoThis() printf("going to do this\n"))
procedure(CCFdidThat() printf("have done that\n"))
CCFaddMenuTriggers(?menu ciwToolsMenu ?preTrigger "CCFdoThis()" ?postTrigger "CCFdidThat()")

Can specify either preTrigger or postTrigger or both.

***************************************************

SCCS Info: @(#) CCFaddMenuTriggers.il 04/19/13.09:45:51 1.1

*/

/***********************************************************************
*                                                                      *
* CCFaddMenuTriggers(?menu menuVar [?preTrigger ""] [?postTrigger ""]) *
*                                                                      *
*   Modify the callbacks in a pulldown menu passed in to either call   *
*      a pre trigger function, a post trigger function, or both.       *
*                                                                      *
*   Slider menus are dealt with by this function recursively calling   *
*                               itself.                                *
*                                                                      *
***********************************************************************/

procedure(CCFaddMenuTriggers(@key menu (preTrigger "") (postTrigger ""))
  let((callback)
    foreach(menuItem hiGetMenuItems(menu)
      if(get(menu menuItem)->hiSubMenu then
        CCFaddMenuTriggers(
          ?menu get(menu menuItem)->hiSubMenu 
          ?preTrigger preTrigger
          ?postTrigger postTrigger
        )
      else
        callback=get(menu menuItem)->_itemCallback
        when(stringp(callback)
          hiSetMenuItemCallback(menu menuItem 
            strcat(preTrigger " " callback " " postTrigger)
          )
        )
      )
    )
    t
  )
)

Thanks Andrew,

Your solution works perfect !!

I am trying 'getCallingFunction' to get the name of invoked function(from drop down menu) in my PreTrigger function but getting only PreTrigger function name (CCFdothis) on all levels of stack. Pre and Post trigger functions are exectued as expected but I am not able to recover the name of the function from drop down menu.

Goal is to find out which function was invoked (from drop dwon menu) and then run a piece of code. Is there any other function I can use to acheieve this ?

Best Regards

getCallingFunction() won't help you, because it hasn't called the real menu function yet. Instead you could use this adapted version of the code:

procedure(CCFaddMenuTriggers(@key menu (trigger ""))
  let((callback)
    foreach(menuItem hiGetMenuItems(menu)
      if(get(menu menuItem)->hiSubMenu then
        CCFaddMenuTriggers(
          ?menu get(menu menuItem)->hiSubMenu 
          ?trigger trigger
        )
      else
        callback=get(menu menuItem)->_itemCallback
        when(stringp(callback) && !blankstrp(trigger)
          hiSetMenuItemCallback(menu menuItem 
            sprintf(nil "%s(%L)" trigger callback)
          )
        )
      )
    )
    t
  )
)

And then:

procedure(CCFdoSomething(realCallback)
  printf("Calling %L\n" realCallback)
  errsetstring(realCallback t)
)
CCFaddMenuTriggers(?menu ciwToolsMenu ?trigger "CCFdoSomething")

You're then responsible for calling the real callback (which gets passed into your trigger function) yourself.

Regards,

Andrew.