Copy pins as strongly connected

I don't think so (during the copy operation). What you can do is copy the pins, and then use Connectivity->Pins->Strongly Connected, and select the original and new pin (then hit escape). That will do it.

Regards,

Andrew.

Indeed, that will do the job for a single pin. But I have hundreds of pins an this function doesn't work on a batch of pins.

Any other way to make a whole batch of pin pairs strongly connected at once, or do I need to script it?

No, it would need some code writing. The VLS XL Connectivity->Pin->Pin Connectivity Setting form won't help either as if you select all the pins and create a strong connect group, you end up with a single terminal with all the pin figures strongly connected which isn't what you want.

I just wrote this which does what you want (I think). Just select all the pins that you want strongly connected, and it will convert them to be strongly connected (on their original terminals).

Andrew

/* abConvertSelectedPinsToStronglyConnected.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Sep 06, 2019 
Modified   
By         

Function to convert selected pin figures to be strongly connected.

abConvertSelectedPinsToStronglyConnected([cv])

***************************************************

SCCS Info: @(#) abConvertSelectedPinsToStronglyConnected.il 09/06/19.09:01:57 1.1

*/

/******************************************************************
*                                                                 *
*         abConvertSelectedPinsToStronglyConnected([cv])          *
*                                                                 *
*   Convert all selected pins which are on the same terminal to   *
* be strongly connected pins (keeping them on the same terminal). *
*             Uses current cellView unless passed in.             *
*                                                                 *
******************************************************************/

procedure(abConvertSelectedPinsToStronglyConnected(@optional (cv geGetEditCellView()))
  let((groupedPinFigures mainPin pinFigs origPin)
    ;--------------------------------------------------------------------
    ; Group the pin figures together to those on the same terminal
    ;--------------------------------------------------------------------
    groupedPinFigures=makeTable('groupedPins nil)
    foreach(obj geGetSelectedSet(cv)
      when(obj~>pin
        groupedPinFigures[obj~>pin~>term]=tconc(groupedPinFigures[obj~>pin~>term] obj)
      )
    )
    ;--------------------------------------------------------------------
    ; Now pick the first pin figure as the master, and move the pin figures
    ; of the rest to be on the same pin as the master, cleaning up any
    ; empty pins as we go
    ;--------------------------------------------------------------------
    foreach(group groupedPinFigures
      pinFigs=car(groupedPinFigures[group])
      mainPin=car(pinFigs)~>pin
      foreach(pinFig cdr(pinFigs)
        origPin=pinFig~>pin
        dbSubFigFromPin(origPin pinFig)
        unless(origPin~>figs
          dbDeleteObject(origPin)
        )
        dbAddFigToPin(mainPin pinFig) 
      )
    )
    t
  )
)

No, it would need some code writing. The VLS XL Connectivity->Pin->Pin Connectivity Setting form won't help either as if you select all the pins and create a strong connect group, you end up with a single terminal with all the pin figures strongly connected which isn't what you want.

I just wrote this which does what you want (I think). Just select all the pins that you want strongly connected, and it will convert them to be strongly connected (on their original terminals).

Andrew

/* abConvertSelectedPinsToStronglyConnected.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Sep 06, 2019 
Modified   
By         

Function to convert selected pin figures to be strongly connected.

abConvertSelectedPinsToStronglyConnected([cv])

***************************************************

SCCS Info: @(#) abConvertSelectedPinsToStronglyConnected.il 09/06/19.09:01:57 1.1

*/

/******************************************************************
*                                                                 *
*         abConvertSelectedPinsToStronglyConnected([cv])          *
*                                                                 *
*   Convert all selected pins which are on the same terminal to   *
* be strongly connected pins (keeping them on the same terminal). *
*             Uses current cellView unless passed in.             *
*                                                                 *
******************************************************************/

procedure(abConvertSelectedPinsToStronglyConnected(@optional (cv geGetEditCellView()))
  let((groupedPinFigures mainPin pinFigs origPin)
    ;--------------------------------------------------------------------
    ; Group the pin figures together to those on the same terminal
    ;--------------------------------------------------------------------
    groupedPinFigures=makeTable('groupedPins nil)
    foreach(obj geGetSelectedSet(cv)
      when(obj~>pin
        groupedPinFigures[obj~>pin~>term]=tconc(groupedPinFigures[obj~>pin~>term] obj)
      )
    )
    ;--------------------------------------------------------------------
    ; Now pick the first pin figure as the master, and move the pin figures
    ; of the rest to be on the same pin as the master, cleaning up any
    ; empty pins as we go
    ;--------------------------------------------------------------------
    foreach(group groupedPinFigures
      pinFigs=car(groupedPinFigures[group])
      mainPin=car(pinFigs)~>pin
      foreach(pinFig cdr(pinFigs)
        origPin=pinFig~>pin
        dbSubFigFromPin(origPin pinFig)
        unless(origPin~>figs
          dbDeleteObject(origPin)
        )
        dbAddFigToPin(mainPin pinFig) 
      )
    )
    t
  )
)

Just tested this, works perfectly. Thank.