ViVa Bookmarks and its usage

Hi Tommaso,

The issue is that the waveform index number in the copy is no longer 1, and so it can't find the waveform. To make it easier, I've just written a wrapper function which allows you to specify the waveform to add the bookmark to by name rather than by index. So you'd change your call to abPlaceBookmarkByName and change the ?waveIndex 1 to ?waveName "/out" (or whatever the signal is called in the plot).

Regards,

Andrew

/* abPlaceBookmarkByName.ils

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       May 28, 2021 
Modified   Jun 02, 2021 
By         A.D.Beckett

Place a bookmark by waveform name rather than index - easier
if the indices are unknown, for example.

abPlaceBookmarkByName( currentWindow() "xrange" list(10e3 10e4)
    ?waveName "/out" ?description "myBookMark" 
    ?properties list(list("fillColor" "red") 
        list("defaultLabel" "defaultBookMark")))

***************************************************

SCCS Info: @(#) abPlaceBookmarkByName.ils 06/02/21.13:27:28 1.2

*/

/**************************************************************************
*                                                                         *
*       (abPlaceBookmarkByName winId bmType location @key waveName        *
*                           parent description                            *
*                      visible subwindow properties)                      *
*                                                                         *
* Wrapper around awvPlaceBookmark which allows you to add a bookmark to a *
* waveform given its name rather than a potentially unknown index number. *
*      The argument list is the same as awvPlaceBookmark except that      *
*                   ?waveIndex is replaced by ?waveName                   *
*                                                                         *
**************************************************************************/

(defun abPlaceBookmarkByName 
  (winId bmType location @key waveName parent description 
          visible subwindow properties)
  (let (transposed waveNameList indexName)
    (setq waveNameList (awvGetWaveNameList winId ?subwindow subwindow))
    (setq transposed
          (foreach mapcar (num name) (car waveNameList) (cadr waveNameList)
                   (list num name)))
    (setq indexName (car (exists indName transposed 
                                 (equal waveName (cadr indName)))))
    (unless indexName
      (error "Unable to find waveform name %L in window %L"
             waveName winId)
      )
    (awvPlaceBookmark winId bmType location
                      ?waveIndex (car indexName) ?parent parent
                      ?description description ?visible visible
                      ?subwindow subwindow ?properties properties
                      )
    )
  )

Hi Tommaso,

The issue is that the waveform index number in the copy is no longer 1, and so it can't find the waveform. To make it easier, I've just written a wrapper function which allows you to specify the waveform to add the bookmark to by name rather than by index. So you'd change your call to abPlaceBookmarkByName and change the ?waveIndex 1 to ?waveName "/out" (or whatever the signal is called in the plot).

Regards,

Andrew

/* abPlaceBookmarkByName.ils

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       May 28, 2021 
Modified   Jun 02, 2021 
By         A.D.Beckett

Place a bookmark by waveform name rather than index - easier
if the indices are unknown, for example.

abPlaceBookmarkByName( currentWindow() "xrange" list(10e3 10e4)
    ?waveName "/out" ?description "myBookMark" 
    ?properties list(list("fillColor" "red") 
        list("defaultLabel" "defaultBookMark")))

***************************************************

SCCS Info: @(#) abPlaceBookmarkByName.ils 06/02/21.13:27:28 1.2

*/

/**************************************************************************
*                                                                         *
*       (abPlaceBookmarkByName winId bmType location @key waveName        *
*                           parent description                            *
*                      visible subwindow properties)                      *
*                                                                         *
* Wrapper around awvPlaceBookmark which allows you to add a bookmark to a *
* waveform given its name rather than a potentially unknown index number. *
*      The argument list is the same as awvPlaceBookmark except that      *
*                   ?waveIndex is replaced by ?waveName                   *
*                                                                         *
**************************************************************************/

(defun abPlaceBookmarkByName 
  (winId bmType location @key waveName parent description 
          visible subwindow properties)
  (let (transposed waveNameList indexName)
    (setq waveNameList (awvGetWaveNameList winId ?subwindow subwindow))
    (setq transposed
          (foreach mapcar (num name) (car waveNameList) (cadr waveNameList)
                   (list num name)))
    (setq indexName (car (exists indName transposed 
                                 (equal waveName (cadr indName)))))
    (unless indexName
      (error "Unable to find waveform name %L in window %L"
             waveName winId)
      )
    (awvPlaceBookmark winId bmType location
                      ?waveIndex (car indexName) ?parent parent
                      ?description description ?visible visible
                      ?subwindow subwindow ?properties properties
                      )
    )
  )

thanks! it would be nice to have this feature implemented in the tool in future releases, in a way to define it in the output setup for instance.

BR,
Tommaso

Hi Tommaso,

Actually, if you create the bookmarks using SKILL, and then save a plotting template from ViVA into the maestro view (which is a new feature in IC6.1.8/ICADVM18.1) then you can plot the graphs again with the same bookmarks as before - this is the preferred way of restoring markers and bookmarks to the graph, and having the same graph arrangement as before.

However, there isn't currently a UI way of adding bookmarks on the graph, which would be needed for this to be really useful and accessible. I believe (from when I've looked at this in the past) that there are requests for this, but the focus with bookmarks was having sufficient support for them to be used programmatically as that was mainly what they were used for (for example, with checks-and-asserts, it can show the region of a waveform with an assertion failure).

You might want to contact customer support to ask for a menu in VIVA to add bookmarks. You might want to mention to the AE CCR 1583128 which talks about some of the incomplete parts of the bookmark implementation right now.

Regards,

Andrew.

Hi Andrew, 
Yes I thought indeed about the plotting template (which I am already using). Thank you for the hint, I will follow up with the customer support.

BR,
Tommaso