How to change pin size in an existing symbol?

Stephan,

The edit properties doesn't have a way to change the pin shape from one to another, but it can be easily achieved with SKILL. Not sure this would particularly help you with analogLib since that's a library shipped with Virtuoso, but anyway here's some code I just threw together to change all the pins in a symbol from square to the small round pins you liked.

Regards,

Andrew

/* abChangeSymbolPinsToRound.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       Apr 13, 2022 
Modified   
By         

Function to change all pins on a symbol to be round
rather than the usual square pins

abChangeSymbolPinsToRound()

***************************************************

SCCS Info: @(#) abChangeSymbolPinsToRound.il 04/13/22.20:40:56 1.1

*/

/***************************************************************
*                                                              *
*    abChangeSymbolPinsToRound([?cvId geGetEditCellView()]     *
*                      [?radius 0.00625])                      *
*                                                              *
*  Change all rectangular/square pins on a symbol to be round  *
*   pins. Both the cvId and radius can be passed as keyword    *
*              arguments to override the default.              *
*                                                              *
***************************************************************/

procedure(abChangeSymbolPinsToRound(@key (cvId geGetEditCellView()) 
    (radius 0.00625))
  let((newPinFig)
    foreach(term cvId~>terminals
      foreach(pin term~>pins
        foreach(fig pin~>figs
          when(fig~>objType=="rect"
            destructuringBind((x y) centerBox(fig~>bBox)
              newPinFig=dbCreateEllipse(
                cvId fig~>lpp list(x-radius:y-radius x+radius:y+radius)
              )
              dbAddFigToPin(pin newPinFig)
              foreach(child fig~>children
                child~>parent=newPinFig
              )
              dbDeleteObject(fig)
            )
          )
        )
      )
    )
    t
  )
)

Hi Andrew,

many thanks for this code, it works fine!

I only tried to make an extension to run this on a whole library:

procedure(changeSymbolPinSizeLib(libN)
let((libId cvId)
libId = ddGetObj(libN)

foreach(cellN libId~>cells~>name
when(dbOpenCellView( libN cellN "symbol")
cvId = dbOpenCellViewByType( libN cellN "symbol" "" "a")

abChangeSymbolPinsToRound()

dbSave(cvId)
dbClose(cvId)
); ** when **
); ** foreach cell **

)
)

Unfortunately I do not see that it works. It loops across all cells, but gives error messages, so that the old big pins are still present.

Do you see a mistake in the code?

Bye Stephan

StephanWeber said:

Do you see a mistake in the code?

Yes, you are not passing the cellView id to abChangeSymbolPinsToRound(), so it would be always editing whatever cellView is in the current window. You would need to call:

abChangeSymbolPinsToRound(cvId)

Andrew

Thanks, again, Andrew! But I still fail with this code:

procedure(changeSymbolPinSizeLib(libN)
let((libId cvId)
libId = ddGetObj(libN)

foreach(cellN libId~>cells~>name
when(dbOpenCellView( libN cellN "symbol")
cvId = dbOpenCellViewByType( libN cellN "symbol" "" "a")
abChangeSymbolPinsToRound(cvId)
dbSave(cvId)
dbClose(cvId)
); ** when **
); ** foreach cell **

)
)

I get this:

*Error* abChangeSymbolPinsToRound: extra arguments or keyword missing - (db:0x8c8e4f9a)

Do you see again, what is wrong?

Bye Stephan 

Stephan,

My mistake. I didn't read my own code. The argument is a keyword rather than positional argument. The line should be:

abChangeSymbolPinsToRound(?cvId cvId)

Andrew

Stephan,

My mistake. I didn't read my own code. The argument is a keyword rather than positional argument. The line should be:

abChangeSymbolPinsToRound(?cvId cvId)

Andrew

Many thanks, Andrew. Now it works fine.