Using "libName" as a function argument

Meant to put the comment in the "SKILL" forum. Sorry.

There should be no issue with "libName" as a function argument.  I do that all the time.   What I immediately suspect is perhaps your code is calling some function that uses libName internally but forgot to add it to a let() to make it local.  I'm attach a concrete example demonstrating a really easy bug to introduce regarding variable scoping in SKILL.  To make things worse, mySubFnBad() might be in a compiled function from a foundry that gets called as part of a library libInit.il.  So you don't even know that someone else's buggy code is stomping on your variable.  I've for sure run into that before.  

;; this code is not so useful but it is at least not broken.  libName is correctly listed in the let() and so it has local scope

procedure(mySubFnGood(txt)

    let( (libName)

        libName = strcat(txt "_mysfx_good")

       ;; return the modified string

        libName

    )

)

;; this broken code does *not* correctly list libName in the let() and so the assignment will overwrite the value of

;; libName in the calling function which can cause frustrating and hard to track down bugs.  Catching this is one of the

;; *huge* benefits of running sklint() because this is a really really easy bug to introduce and it can lurk for years before

;; causing problems.  

procedure(mySubFnBad(txt)

    let( (libname) ;; misspelled libName here on purpose, but we could just as easily have forgotten to include libName in the list

        libName = strcat(txt "_mysfx_bad")

       ;; return the modified string

        libName

    )

)

;; nothing in this code intentionally modifies the libName argument
procedure(myTopFn(libName)

   let( (r)

        printf("called %s(%L)\n" getCallingFunction(0) libName)

        r = mySubFnGood(libName)

        printf("mySubFnGood() returned %L and now libName = %L\n" r libName)

        r = mySubFnBad(libName)

        printf("mySubFnBad() returned %L and now libName = %L\n" r libName)

  )

)

myTopFn("myLib")

The variable got passed to the function as an argument. I could be wrong but I don't think an argument can be localized.

correct, but does your function call any other functions?  If so, look in those other functions to see if any used `libName` as an internal variable and forgot to localize it.

Dan's suggestion is highly likely to be the reason here. SKILL has dynamic scoping (SKILL++ uses lexical scoping and won't have this problem) - so that means that each variable ends up as a stack - each time you enter a new scope (e.g. a variable defined in a let, or as an argument to a function - note that function arguments are local to the function itself), then any variable access during the run time of the function or its descendants will see whatever is top of the stack. I cover this a little in my Writing Good SKILL Code video (search on support.cadence.com for this). So any function you call which fails to declare a variable as local can capture a variable with the same name in any parent function (this is the nature of dynamic scoping).

Andrew

Dan's suggestion is highly likely to be the reason here. SKILL has dynamic scoping (SKILL++ uses lexical scoping and won't have this problem) - so that means that each variable ends up as a stack - each time you enter a new scope (e.g. a variable defined in a let, or as an argument to a function - note that function arguments are local to the function itself), then any variable access during the run time of the function or its descendants will see whatever is top of the stack. I cover this a little in my Writing Good SKILL Code video (search on support.cadence.com for this). So any function you call which fails to declare a variable as local can capture a variable with the same name in any parent function (this is the nature of dynamic scoping).

Andrew