Shortcut to Open Layout View of Currently Open Cell in New Tab

Hi Sgcad,

There was a post about changing between schematic and layout views, so maybe this will help you as an starting point. 

/**********CHANGE BETWEEN SCHEMATIC AND LAYOUT (bindkeys on bottom)*********/

;also asks to create the cell in case don't exists.

procedure(myOpenOtherView(@optional (viewName nil) (cv geGetEditCellView()))

  let((cellWin otherCv msg dbox viewType)

    unless(stringp(viewName)

        if(cv~>viewName=="schematic" then

            viewName="layout"

            viewType="maskLayout"

        else

            viewName="schematic"

            viewType="schematic"

        )

    )

    otherCv = dbOpenCellViewByType(cv~>libName cv~>cellName viewName)

    if(otherCv then

        unless(geGetCellViewWindow(otherCv)

            deOpenCellView(otherCv~>libName otherCv~>cellName otherCv~>viewName viewType nil "r")

        ) ;unless

        cellWin=geGetCellViewWindow(otherCv)

        hiDeiconifyWindow(cellWin)

        hiSetCurrentWindow(cellWin)

        hiRaiseWindow(cellWin)

    else

        hiGetAttention()

        sprintf(msg "**WARNING: Could not open %s %s %L\n" cv~>libName cv~>cellName viewName)

        sprintf(msg "%s           Would you like to create this view?\n" msg)          

        dbox=hiDisplayAppDBox(?name 'dBox ?buttonLayout 'YesNo ?dboxText msg ?dboxBanner "Create this view?")

        if(dbox then

            printf("Creating: %s %s %L\n" cv~>libName cv~>cellName viewName)

            if(otherCv = dbOpenCellViewByType(cv~>libName cv~>cellName viewName viewType "a") then

                deOpenCellView(otherCv~>libName otherCv~>cellName otherCv~>viewName viewType nil "a")

            else

                hiGetAttention()

                printf("**ERROR: Could not create %s %s %L\n" cv~>libName cv~>cellName viewName)

            )

        else

            printf("Cell view %s %s %L does not exist and was not created\n" cv~>libName cv~>cellName viewName)

        )

    )

    otherCv

  ) ;let

) ;proc

hiSetBindKey("Layout" "Shift<Key>w" "myOpenOtherView()")

hiSetBindKey("Schematics" "Shift<Key>w" "myOpenOtherView()")

Also, if this wasn't what you were looking for, please, add your Cadence Version with: getVersion() and getVersion("virtuoso")
This in case somebody needs it.

Regards,
R. Gómez

Thanks, that helped. For completeness, the post you mentioned is here: How to open a schematic window from a layout window and the resulting code (for Virtuoso 6.1.8) as follows:

hiSetBindKey("Schematics" "<key>F12"
  "geOpen(
    ?window hiGetCurrentWindow()~>sessionWindow
    ?lib geGetEditCellView()~>libName
    ?cell geGetEditCellView()~>cellName
    ?view \"symbol\"
    ?mode \"r\"
  )"
)

I still wonder if there's a simple way to replace the first line with something that allows this shortcut to work also from other views, instead of repeating the hiSetBindKey many times for every view type I'd like to support?

You could add a simple loop around this to define it for more than one application:

foreach(application '("Schematics" "Symbol" "Layout")
  hiSetBindKey(application "<key>F12"
    "geOpen(
      ?window hiGetCurrentWindow()~>sessionWindow
      ?lib geGetEditCellView()~>libName
      ?cell geGetEditCellView()~>cellName
      ?view \"symbol\"
      ?mode \"r\"
    )"
  )
)

Andrew

Adding to what Andrew said, you could use deGetAllRootTypes() to get all View-types an iterate over that.

Also there is a post Method for raising a specific design window from a list in which they list and raise opened windows. This as another workaround where you can choose which one to open.

Regards,
R.Gómez

Adding to what Andrew said, you could use deGetAllRootTypes() to get all View-types an iterate over that.

Also there is a post Method for raising a specific design window from a list in which they list and raise opened windows. This as another workaround where you can choose which one to open.

Regards,
R.Gómez

RicardoGV1 said:

Adding to what Andrew said, you could use deGetAllRootTypes() to get all View-types an iterate over that.

Although most of those applications wouldn't make sense given that geGetEditCellView() wouldn't work on them all. So buyer beware...

Andrew