Use for loop to create dynamic field in hiCreateAppForm

let((group_instance symmetry allList startx starty width height)

    allList = nil
    startx = 0
    starty = 210
    width = 600
    height = 30

    for(i 0 9
        ; use concat to give each field a unique name
        group_instance = hiCreateStringField(
            ?name concat('instances i)
            ?prompt "Group instances"
        )
        symmetry = hiCreateRadioField(
            ?name concat('symmetry i)
            ?prompt "Device symmetry"
            ?choices list("Y" "N")
            ?value "Y"
        ; commented callback out for now as this needs to be a list
        ;    ?callback "symmetry1CB(hiGetCurrentForm())"
        )
        finalx = startx
        ; add a *2 to stop the fields overlapping
        finaly = 210 + (i*height*2)
        finalx_f2 = finalx
        finaly_f2 = finaly + height
        ; added prompt widths
        flist = list(
            list(group_instance finalx:finaly width:height 120) 
            list(symmetry finalx_f2:finaly_f2 width:height 120)
        )
        ; should really consider whether append is the right approach
        ; if there are many fields (lists are sequential). Maybe lconc or
        ; build list using cons and then reverse() at the end?
        allList = append(allList flist)
    )

    hiCreateAppForm(
        ?name 'ExampleForm
        ?formTitle "example form"
        ?callback 'ExampleFormCB
        ?fields allList
    )
)

Hi Andrew,

Thank you for your code. It clarifies my SKILL concept.  How do I pass a list of callback procedures in "?callback argument" inside for loop in this case since each radio field has its own callback procedure? 

?callback list("symmetryCB(hiGetCurrentForm())")    ?

symmetry = hiCreateRadioField(
?name concat('symmetry i)
?prompt "Device symmetry"
?choices list("Y" "N")
?value "Y"
; commented callback out for now as this needs to be a list
; ?callback "symmetry1CB(hiGetCurrentForm())"
)

Thanks,

ManChak

Hi ManChak,

In this example, I use a common callback function, but pass in the field names to the callback so that the common callback can retrieve the associated fields. The other approach would be to construct the callback function name using sprintf in a similar fashion (so it could be symmetry%dCB for example).

Andrew.

procedure(symmetryCB(form symmetry instances)
    printf("symmetry is %s\n" get(form symmetry)->value)
    printf("instances is %s\n" get(form instances)->value)
)

let((group_instance symmetry allList startx starty width height)

    allList = nil
    startx = 0
    starty = 210
    width = 600
    height = 30

    for(i 0 9
        ; use concat to give each field a unique name
        group_instance = hiCreateStringField(
            ?name concat('instances i)
            ?prompt "Group instances"
        )
        symmetry = hiCreateRadioField(
            ?name concat('symmetry i)
            ?prompt "Device symmetry"
            ?choices list("Y" "N")
            ?value "Y"
            ?callback list(
                sprintf(nil 
                    "symmetryCB(hiGetCurrentForm() 'symmetry%d 'instances%d)"
                    i i
                )
            )
        )
        finalx = startx
        ; add a *2 to stop the fields overlapping
        finaly = 210 + (i*height*2)
        finalx_f2 = finalx
        finaly_f2 = finaly + height
        ; added prompt widths
        flist = list(
            list(group_instance finalx:finaly width:height 120) 
            list(symmetry finalx_f2:finaly_f2 width:height 120)
        )
        ; should really consider whether append is the right approach
        ; if there are many fields (lists are sequential). Maybe lconc or
        ; build list using cons and then reverse() at the end?
        allList = append(allList flist)
    )

    hiCreateAppForm(
        ?name 'ExampleForm
        ?formTitle "example form"
        ?callback 'ExampleFormCB
        ?fields allList
    )
)

Hi Andrew,

Thank you for your help. I will try the code.

ManChak

Hi Andrew,

I use your code above to create "allList". I get syntax syntax if I use the following code for  hiCreateAppForm.

I know item1 solution should work, but I prefer item2 solution if possible. I just want "allList" contains fields defined in the for loop.

1) Do I need to add templateField, templateLoad, templateSave, sep1, libName to allList ?

OR 

2) ?fields argument could accept multiple list ?

hiCreateAppForm(
   ?name 'ExampleForm
   ?formTitle "example form"
   ?callback 'ExampleFormCB
   ?fields
   list(
      list(templateFile 0:0 600:30 200)
      list(templateLoad 100:5 45:20)
      list(templateSave 150:5 45:20)
      list(sep1 0:35 600:0)
      list(libName 0:40 600:30 200)
      allList
  ) )

*WARNING* promptWidth attribute must be a positive integer:
*WARNING* ((stringStruct@0x2ed5fcb0 (0 210) (600 30) 120) (radioStruct@0x2ed5fcc8 (0 240) (600 30) 120) (stringStruct@0x2ed5fce0 (0 270) (600 30) 120) (radioStruct@0x2ed5fcf8 (0 300) (600 30) 120) (stringStruct@0x2ed5fd10 (0 330) (600 30) 120) (radioStruct@0x2ed5fd28 (0 360) (600 30) 120) (stringStruct@0x2ed5fd40 (0 390) (600 30) 120) (radioStruct@0x2ed5fd58 (0 420) (600 30) 120) (stringStruct@0x2ed5fd70 (0 450) (600 30) 120) (radioStruct@0x2ed5fd88 (0 480) (600 30) 120) (stringStruct@0x2ed5fda0 (0 510) (600 30) 120
*Error* hiCreateAppForm: not all fields have 2D attributes specified,
and/or illegal attribute values

Thanks,

ManChak

It fails because the list would be the wrong structure - you'd have the allList within the list with the other fields. You'd need to do (and I didn't test this because I don't have your other fields defined, but it should work):

hiCreateAppForm(
   ?name 'ExampleForm
   ?formTitle "example form"
   ?callback 'ExampleFormCB
   ?fields
   append(
     list(
        list(templateFile 0:0 600:30 200)
        list(templateLoad 100:5 45:20)
        list(templateSave 150:5 45:20)
        list(sep1 0:35 600:0)
        list(libName 0:40 600:30 200)
     )
     allList
   )
)

Andrew

Hi Andrew,

1. Thank you for your help. It works,

2. I have one question about your suggestion in the previous response. I tried lconc and cons in my code. According to SKILL manual, one argument of cons is item instead of list. 

Unlike append command,  "lconc" merges two lists together. How could I replace "append" command with either cons or lconc command to build allList ?

    x = tconc(nil 1) ; x is initialized ((1) 1)
lconc(x '(2 3 4)) ; x is now ((1 2 3 4) 4)
lconc(x nil) ; Nothing is added to x.
lconc(x '(5)) ; x is now ((1 2 3 4 5) 5)
   x = car( x ) ; x is now (1 2 3 4 5)

flist = list(
list(group_instance finalx:finaly width:height 120)
list(symmetry finalx_f2:finaly_f2 width:height 120)
)
; should really consider whether append is the right approach
; if there are many fields (lists are sequential). Maybe lconc or
; build list using cons and then reverse() at the end?

allList = append(allList flist)

Thanks,

ManChak

ManChak,

Here's the first version, using lconc:

procedure(symmetryCB(form symmetry instances)
    printf("symmetry is %s\n" get(form symmetry)->value)
    printf("instances is %s\n" get(form instances)->value)
)

let((group_instance symmetry allList startx starty width height
        templateFile templateLoad templateSave sep1 libName)

    templateFile = hiCreateStringField(
        ?name 'templateFile
        ?prompt "Template File"
    )
    templateLoad = hiCreateButton(
        ?name 'templateLoad
        ?buttonText "Load"
    )
    templateSave = hiCreateButton(
        ?name 'templateSave
        ?buttonText "Save"
    )
    sep1 = hiCreateSeparatorField(
        ?name 'sep1
    )
    libName = hiCreateStringField(
        ?name 'libName
        ?prompt "Library Name"
    )

    allList = nil
    startx = 0
    starty = 210
    width = 600
    height = 30

    for(i 0 9
        ; use concat to give each field a unique name
        group_instance = hiCreateStringField(
            ?name concat('instances i)
            ?prompt "Group instances"
        )
        symmetry = hiCreateRadioField(
            ?name concat('symmetry i)
            ?prompt "Device symmetry"
            ?choices list("Y" "N")
            ?value "Y"
            ?callback list(
                sprintf(nil 
                    "symmetryCB(hiGetCurrentForm() 'symmetry%d 'instances%d)"
                    i i
                )
            )
        )
        finalx = startx
        ; add a *2 to stop the fields overlapping
        finaly = 210 + (i*height*2)
        finalx_f2 = finalx
        finaly_f2 = finaly + height
        ; added prompt widths
        flist = list(
            list(group_instance finalx:finaly width:height 120) 
            list(symmetry finalx_f2:finaly_f2 width:height 120)
        )
	; Example using lconc
	; was using append here
        allList = lconc(allList flist)
    )
    allList=car(allList)

    hiCreateAppForm(
        ?name 'ExampleForm
        ?formTitle "example form"
        ?callback 'ExampleFormCB
        ?fields 
            append(
                list(
                    list(templateFile 0:0 600:30 200)
                    list(templateLoad 100:5 45:20)
                    list(templateSave 150:5 45:20)
                    list(sep1 0:35 600:0)
                    list(libName 0:40 600:30 200)
                )
                allList
            )
    )
)

Here's using cons and reverse:

procedure(symmetryCB(form symmetry instances)
    printf("symmetry is %s\n" get(form symmetry)->value)
    printf("instances is %s\n" get(form instances)->value)
)

let((group_instance symmetry allList startx starty width height
        templateFile templateLoad templateSave sep1 libName)

    templateFile = hiCreateStringField(
        ?name 'templateFile
        ?prompt "Template File"
    )
    templateLoad = hiCreateButton(
        ?name 'templateLoad
        ?buttonText "Load"
    )
    templateSave = hiCreateButton(
        ?name 'templateSave
        ?buttonText "Save"
    )
    sep1 = hiCreateSeparatorField(
        ?name 'sep1
    )
    libName = hiCreateStringField(
        ?name 'libName
        ?prompt "Library Name"
    )

    allList = nil
    startx = 0
    starty = 210
    width = 600
    height = 30

    for(i 0 9
        ; use concat to give each field a unique name
        group_instance = hiCreateStringField(
            ?name concat('instances i)
            ?prompt "Group instances"
        )
        symmetry = hiCreateRadioField(
            ?name concat('symmetry i)
            ?prompt "Device symmetry"
            ?choices list("Y" "N")
            ?value "Y"
            ?callback list(
                sprintf(nil 
                    "symmetryCB(hiGetCurrentForm() 'symmetry%d 'instances%d)"
                    i i
                )
            )
        )
        finalx = startx
        ; add a *2 to stop the fields overlapping
        finaly = 210 + (i*height*2)
        finalx_f2 = finalx
        finaly_f2 = finaly + height
        ; added prompt widths
	; now using cons to construct the list - more efficient since
	; it adds to the beginning
	allList=cons(list(group_instance finalx:finaly width:height 120) allList)
	allList=cons(list(symmetry finalx_f2:finaly_f2 width:height 120) allList)
    )
    ; the fields all appear OK even if you don't reverse, but if
    ; you use tab to move through the fields, they are in the wrong order
    ; unless you reverse the list to be from top to bottom
    allList=reverse(allList)

    hiCreateAppForm(
        ?name 'ExampleForm
        ?formTitle "example form"
        ?callback 'ExampleFormCB
        ?fields 
            append(
                list(
                    list(templateFile 0:0 600:30 200)
                    list(templateLoad 100:5 45:20)
                    list(templateSave 150:5 45:20)
                    list(sep1 0:35 600:0)
                    list(libName 0:40 600:30 200)
                )
                allList
            )
    )
)

Andrew.

ManChak,

Here's the first version, using lconc:

procedure(symmetryCB(form symmetry instances)
    printf("symmetry is %s\n" get(form symmetry)->value)
    printf("instances is %s\n" get(form instances)->value)
)

let((group_instance symmetry allList startx starty width height
        templateFile templateLoad templateSave sep1 libName)

    templateFile = hiCreateStringField(
        ?name 'templateFile
        ?prompt "Template File"
    )
    templateLoad = hiCreateButton(
        ?name 'templateLoad
        ?buttonText "Load"
    )
    templateSave = hiCreateButton(
        ?name 'templateSave
        ?buttonText "Save"
    )
    sep1 = hiCreateSeparatorField(
        ?name 'sep1
    )
    libName = hiCreateStringField(
        ?name 'libName
        ?prompt "Library Name"
    )

    allList = nil
    startx = 0
    starty = 210
    width = 600
    height = 30

    for(i 0 9
        ; use concat to give each field a unique name
        group_instance = hiCreateStringField(
            ?name concat('instances i)
            ?prompt "Group instances"
        )
        symmetry = hiCreateRadioField(
            ?name concat('symmetry i)
            ?prompt "Device symmetry"
            ?choices list("Y" "N")
            ?value "Y"
            ?callback list(
                sprintf(nil 
                    "symmetryCB(hiGetCurrentForm() 'symmetry%d 'instances%d)"
                    i i
                )
            )
        )
        finalx = startx
        ; add a *2 to stop the fields overlapping
        finaly = 210 + (i*height*2)
        finalx_f2 = finalx
        finaly_f2 = finaly + height
        ; added prompt widths
        flist = list(
            list(group_instance finalx:finaly width:height 120) 
            list(symmetry finalx_f2:finaly_f2 width:height 120)
        )
	; Example using lconc
	; was using append here
        allList = lconc(allList flist)
    )
    allList=car(allList)

    hiCreateAppForm(
        ?name 'ExampleForm
        ?formTitle "example form"
        ?callback 'ExampleFormCB
        ?fields 
            append(
                list(
                    list(templateFile 0:0 600:30 200)
                    list(templateLoad 100:5 45:20)
                    list(templateSave 150:5 45:20)
                    list(sep1 0:35 600:0)
                    list(libName 0:40 600:30 200)
                )
                allList
            )
    )
)

Here's using cons and reverse:

procedure(symmetryCB(form symmetry instances)
    printf("symmetry is %s\n" get(form symmetry)->value)
    printf("instances is %s\n" get(form instances)->value)
)

let((group_instance symmetry allList startx starty width height
        templateFile templateLoad templateSave sep1 libName)

    templateFile = hiCreateStringField(
        ?name 'templateFile
        ?prompt "Template File"
    )
    templateLoad = hiCreateButton(
        ?name 'templateLoad
        ?buttonText "Load"
    )
    templateSave = hiCreateButton(
        ?name 'templateSave
        ?buttonText "Save"
    )
    sep1 = hiCreateSeparatorField(
        ?name 'sep1
    )
    libName = hiCreateStringField(
        ?name 'libName
        ?prompt "Library Name"
    )

    allList = nil
    startx = 0
    starty = 210
    width = 600
    height = 30

    for(i 0 9
        ; use concat to give each field a unique name
        group_instance = hiCreateStringField(
            ?name concat('instances i)
            ?prompt "Group instances"
        )
        symmetry = hiCreateRadioField(
            ?name concat('symmetry i)
            ?prompt "Device symmetry"
            ?choices list("Y" "N")
            ?value "Y"
            ?callback list(
                sprintf(nil 
                    "symmetryCB(hiGetCurrentForm() 'symmetry%d 'instances%d)"
                    i i
                )
            )
        )
        finalx = startx
        ; add a *2 to stop the fields overlapping
        finaly = 210 + (i*height*2)
        finalx_f2 = finalx
        finaly_f2 = finaly + height
        ; added prompt widths
	; now using cons to construct the list - more efficient since
	; it adds to the beginning
	allList=cons(list(group_instance finalx:finaly width:height 120) allList)
	allList=cons(list(symmetry finalx_f2:finaly_f2 width:height 120) allList)
    )
    ; the fields all appear OK even if you don't reverse, but if
    ; you use tab to move through the fields, they are in the wrong order
    ; unless you reverse the list to be from top to bottom
    allList=reverse(allList)

    hiCreateAppForm(
        ?name 'ExampleForm
        ?formTitle "example form"
        ?callback 'ExampleFormCB
        ?fields 
            append(
                list(
                    list(templateFile 0:0 600:30 200)
                    list(templateLoad 100:5 45:20)
                    list(templateSave 150:5 45:20)
                    list(sep1 0:35 600:0)
                    list(libName 0:40 600:30 200)
                )
                allList
            )
    )
)

Andrew.

Hi Andrew,

Thank you for your examples. It is very useful to me.

Thanks,

ManChak