define different but related parameters in array of stimuli to ADE

Hi Chris,

I'd do this with a Verilog-A model:

// VerilogA for mylib, delayedSrcs, veriloga

`include "constants.vams"
`include "disciplines.vams"
`define NUMBITS 128
module delayedSrcs(src);
output [`NUMBITS-1:0] src;
electrical [`NUMBITS-1:0] src;

parameter real td=10n;      // initial delay
parameter real trf=1n;      // rise and fall time
parameter real offset=50n;  // offset delay between bits
parameter real val0=0.0;    // low voltage
parameter real val1=1.2;    // high voltage
parameter real width=100n;  // width of pulse. Set to 0 if you don't want it to go low again
parameter real period=0.0;  // period of pulse once started. 0 means one shot (not periodic)

integer srcVal;
genvar bit;

analog begin
    // if period is 0, then the pulse is a one-shot. Otherwise it's
    // periodic
    @(timer(td,period)) begin
        srcVal=1;
    end
    // this allows the pulse to return to 0. If you don't want that
    // set the width parameter to (can be set on the instance)
    @(timer(td+trf+width,period)) begin
        if (width>0) begin
            srcVal=0;
        end
    end
    // Generate all the delayed sources
    for(bit=0; bit<`NUMBITS; bit=bit+1) begin
        V(src[bit]) <+ transition(srcVal*(val1-val0)+val0,offset*bit,trf);
    end

end

endmodule

If you create a Verilog-A view inside Virtuoso (I called the cell "delayedSrcs"), it will then ask you to create a symbol. When you instantiate it, you can use the "Tool Filter" to see the parameters - you might in your case want to set width to 0 on the instance if you don't want the pulses to return to 0 after going high.

Another possibility would have been to create a schematic PCell, but I think the VerilogA approach is simpler in this case.

Regards,

Andrew.

Hi Andrew

Thanks - that's incredibly helpful.  Didn't even know I could do anything like this; this should be fun.

Chris