How to convert analog value to digital in calculator

Try:

if(value(VT("aaa") 1.0e-6) > 1.0 then 1 else 0)

Regards,

Andrew

Unfortunately doesn't work:

- Warning -
<Calculator>
Evaluation error(ERROR : ("greaterp" 12 t nil ("*Error* greaterp: can't handle (drwave:261157656 > 1.0)"))). Expression: if(value(VT("/I8/osb<7>") 6.5e-05) > 1.0 then 1 else 0)*128

Unfortunately doesn't work:

- Warning -
<Calculator>
Evaluation error(ERROR : ("greaterp" 12 t nil ("*Error* greaterp: can't handle (drwave:261157656 > 1.0)"))). Expression: if(value(VT("/I8/osb<7>") 6.5e-05) > 1.0 then 1 else 0)*128

It's getting a waveform (I'm guessing you're doing this on ADE XL/Explorer/Assembler results, or doing a parametric sweep), so you need something more complex. Probably using abApplyToWave found in this post would help. Probably better to use this newer version that can be more easily registered with the calculator.

You could then do something like:

abApplyToWave(lambda((val) if(val>1.0 then 1 else 0)) value(VT("aaa") 1.0e-6))

Note, I didn't test this, but I think that would be OK. Anyway, here's the updated code:

/* abApplyToWave.il

Author     A.D.Beckett
Group      Custom IC (UK), Cadence Design Systems Ltd.
Language   SKILL
Date       May 24, 2011 
Modified   Dec 20, 2017 
By         A.D.Beckett

Function to apply a unary function to every element
in a waveform. For example:

abApplyToWave('round waveform)

This can be registered with the calculator using the fx
button in the Function Panel in IC617 and later. Includes
the GUI builder template

***************************************************

SCCS Info: @(#) abApplyToWave.il 12/20/17.14:21:36 1.5

*/

/******************************************************************
*                                                                 *
*                    (abApplyToWave func arg)                     *
*                                                                 *
*  And finally, the function that does the work. You give it the  *
*  name of a unary function (takes one argument) which works on   *
* numbers, and then this is applied to all members of a waveform. *
*                      Handles families too.                      *
*                                                                 *
******************************************************************/
(defun abApplyToWave (func arg)
  ;----------------------------------------------------------------------
  ; convert string function name to symbol
  ;----------------------------------------------------------------------
  (when (stringp func)
    (setq func (concat func)))
  (cond 
    ((numberp arg) (funcall func arg))
    ((drIsDataVector arg) (vecMap 'abApplyToWave func arg))
    ((drIsWaveform arg) 
     ;-------------------------------------------------------------------
     ; Create new waveform, but transfer units if not set on 
     ; new waveform already. This ensures plotting on the same y-axis
     ;-------------------------------------------------------------------
     (let (new yVec)
       (setq new (wfMap 'abApplyToWave func arg))
       (setq yVec (drGetWaveformYVec new))
       (unless (getq yVec units)
         (putpropq yVec (getq (drGetWaveformYVec arg) units) units)
         )
       new
       )
     )
    ((famIsFamily arg) (famMap 'abApplyToWave func arg))
    (t
      (error "abApplyToWave: can't apply %L to %L\n"
             func arg)
      )
    )
  )

;
;;;;;;;;;;;;;;;;;;;;;;;;;; GUI builder information ;;;;;;;;;;;;;;;;;;;;;;;;;;;
ocnmRegGUIBuilder(
 '(nil
  function abApplyToWave
  name abApplyToWave
  description "Apply func to waveform"
  category ("Custom Functions")
  analysis (nil
      general (nil
        args (func arg )
          signals (nil
                arg (nil
                      prompt "Signal"
                      tooltip "Signal"
                      )
           )
          params(nil
                 func (nil
                       prompt "Function Name"
                       tooltip "Name of function"
                       guiRowHint 0
                       type string
                       default "round"
                       required t
                 )
          )
        inputrange t
      )
  )
  outputs(result)
 )
)